Re: Fun with C

[Maciej Sobczak <see.my.homepage@gmail.com>]

On Apr 27, 10:00 am, "Dmitry A. Kazakov" <mail...@dmitry-kazakov.de>
wrote:

> >>> What? A simple hanging spring can oscillate while being purely linear.

> No, I mean that x(t) =A sin(2Pi f t) + x0 is not a linear function of time.

You got it backwards. Completely.

The above equation does not define the spring mechanics. It only
describes the *observable effect* of this mechanics. In other words,
harmonic oscillation is not a cause of spring movement, it is a
consequence of the spring being a linear system. The spring itself has
no idea that it should oscillate at all.

Let's bring some Ada back to this discussion:

with Ada.Text_IO;

procedure Spring is

   Initial_Position : constant := 0.0;
   Initial_Velocity : constant := 10.0;
   Spring_Rigidity  : constant := 1.0;
   Mass             : constant := 1.0;
   Time_Unit        : constant := 0.1;

   Position : Long_Float := Initial_Position;
   Velocity : Long_Float := Initial_Velocity;

   procedure Show_Position is
      P : Integer := 40 + Integer (Position);
      Off_Screen : Boolean := False;
   begin
      if P <= 0 then
         P := 0;
         Off_Screen := True;
      end if;
      if P >= 79 then
         P := 79;
         Off_Screen := True;
      end if;

      for I in 1 .. P loop
         Ada.Text_IO.Put (' ');
      end loop;

      if not Off_Screen then
         Ada.Text_IO.Put ('*');
      else
         Ada.Text_IO.Put ('!');
      end if;
      Ada.Text_IO.New_Line;
   end Show_Position;

   procedure Compute_New_Position is
      Force : Long_Float;
      Acceleration : Long_Float;
      Shift : Long_Float;
   begin
      Force := -1.0 * Position * Spring_Rigidity;
      Acceleration := Force / Mass;
      Velocity := Velocity + Acceleration * Time_Unit;
      Shift := Velocity * Time_Unit;
      Position := Position + Shift;
   end Compute_New_Position;

begin
   loop
      Show_Position;
      delay Time_Unit;
      Compute_New_Position;
   end loop;
end Spring;

The above program is a discrete simulator of a purely linear system.
The sine function is never used there and the program has no freaking
idea that it should oscillate in a harmonic way. Yet it does. Enjoy!

I don't care about the exact math, but as far as I understand it,
purely harmonic oscillations (that is, a single component in the
spectrum) come from purely linear systems. If the underlying system is
not linear, then the resulting oscillation (if it exists at all) will
include additional harmonics. Try to mess with the equations in the
above program, like make the force a square function of position or
make force dependent also on velocity, etc. and the oscillation will
become less pure. I leave to math geeks to come up with exact Fourier
spectrum for each such tweak.

In which case I still don't understand what you have failed to prove.
But hey, at least the discussion is related to Ada again. :-)

--
Maciej Sobczak * http://www.msobczak.com * http://www.inspirel.com