determining input data type

determining input data type

[jedivaughn]

Hi, How is the best way to determine the type of input. I have the
input coming in through a string but if the contents of the string is
an integer then I want to convert it to such. This seems like it
should be very easy to do but I can't seem to find out how to do it
any where.


Thanks,

John

Re: determining input data type

[Jeffrey R. Carter]

jedivaughn wrote:
> Hi, How is the best way to determine the type of input. I have the
> input coming in through a string but if the contents of the string is
> an integer then I want to convert it to such. This seems like it
> should be very easy to do but I can't seem to find out how to do it
> any where.

You could use Integer'Value. If it succeeds, than it represents an Integer. If 
it fails, then it doesn't.

-- 
Jeff Carter
"Why don't you bore a hole in yourself and let the sap run out?"
Horse Feathers
49

Re: determining input data type

[Paul]

Or you could test for characters in the range '0' .. '9'.  You'll still need 
to wrap it up inside an exception handler.

Paul

"Jeffrey R. Carter" <spam.jrcarter.not@spam.acm.org> wrote in message 
news:M8bKk.392682$yE1.130775@attbi_s21...
> jedivaughn wrote:
>> Hi, How is the best way to determine the type of input. I have the
>> input coming in through a string but if the contents of the string is
>> an integer then I want to convert it to such. This seems like it
>> should be very easy to do but I can't seem to find out how to do it
>> any where.
>
> You could use Integer'Value. If it succeeds, than it represents an 
> Integer. If it fails, then it doesn't.
>
> -- 
> Jeff Carter
> "Why don't you bore a hole in yourself and let the sap run out?"
> Horse Feathers
> 49 

Re: determining input data type

[deadlyhead]

On Oct 17, 5:48 pm, jedivaughn <jedivaugh...@gmail.com> wrote:
> Hi, How is the best way to determine the type of input. I have the
> input coming in through a string but if the contents of the string is
> an integer then I want to convert it to such. This seems like it
> should be very easy to do but I can't seem to find out how to do it
> any where.
>
> Thanks,
>
> John

Exceptions are a wonderful thing:

--  file: int_test.adb
--  Tests to see if an input string is an integer

with Ada.Text_IO;   use Ada.Text_IO;
with Ada.Integer_Text_IO;  use Ada.Integer_Text_IO;

procedure Int_Test is

   My_Int : Integer;

begin

   Put("Give me some input, and I will tell you if it is an integer:
");
   Get(My_Int);

   Put(My_Int, 0);
   Put(" is an integer!");
   New_Line;

exception
   when Data_Error =>
      Put("That was not an integer!");
      New_Line;
end Int_Test;

Using Ada.Integer_Text_IO.Get does some work for you, though.  For
instance, if the user inputs 214yy0, it puts 214 in My_Int and
continues on its way.  This may not be what you want, thus some actual
text processing may be in order.

-- deadlyhead

Re: determining input data type

[Dmitry A. Kazakov]

On Fri, 17 Oct 2008 23:53:54 -0700 (PDT), deadlyhead wrote:

> Using Ada.Integer_Text_IO.Get does some work for you, though.  For
> instance, if the user inputs 214yy0, it puts 214 in My_Int and
> continues on its way.  This may not be what you want, thus some actual
> text processing may be in order.

Yes, this was one of the motivations behind:

   http://www.dmitry-kazakov.de/ada/strings_edit.htm 

Your example reworked for Strings_Edit:

with Ada.Text_IO;            use Ada.Text_IO;
with Strings_Edit.Integers;  use Strings_Edit.Integers;

procedure Int_Test is
   My_Int : Integer;
begin
   Put ("Give me some input, and I will tell you if it is an integer:");
   My_Int := Value (Get_Line);
   Put_Line (Image (My_Int) & " is an integer!");
exception
   when Constraint_Error =>
      Put_Line ("That was a too large integer!");
   when End_Error =>
      Put_Line ("You entered nothing!");
   when Data_Error =>
      Put_Line ("That was not an integer!");
end Int_Test;

The function Value takes care to check the whole string for containing
integer and nothing but integer.

-- 
Regards,
Dmitry A. Kazakov
http://www.dmitry-kazakov.de

Re: determining input data type

[anon]

--
-- Without knowing what format your data is in it is kind of 
-- hard to decide what way is the best. Some ways are easy 
-- while others are more complex
--
-- But if the data is a packed buffer string then you could use 
-- Ada.Characters.Handling.Is_Digit.
--
-- In this case the best was is to use a loop and search for all 
-- valid data where the search routine would find the integer 
-- value and no error occurs unless the data is float. Also in this 
-- example, only base 10 integers are valid.
--
with Ada.Text_IO ;
use Ada.Text_IO ;

with Ada.Integer_Text_IO ;
use Ada.Integer_Text_IO ;

with Ada.Characters.Handling ;
use  Ada.Characters.Handling ;

procedure b is

  Data_Error : exception ;

  function To_Integer ( Buffer : String ) return Integer is

    Index : Natural ;
    First : Natural ; -- first valid digit
    Last  : Natural ; -- Last valid digit

  begin -- To_Integer
    Index := Buffer'First ;
    while Index <= Buffer'Last and then 
          not is_digit ( Buffer ( Index ) ) loop 
      Index := Index + 1 ;
    end loop ;
    First := Index ; 

    while Index <= Buffer'Last and then
          is_digit ( Buffer ( Index ) ) loop 
      Index := Index + 1 ;
    end loop ;
    Last := Index - 1 ;

    --  check for decimal point aka the number is float

    if Index <= Buffer'Last and then
       Buffer ( Index ) = '.' then  
       raise Data_Error ;
    end if ;
  
    return Integer'Value ( Buffer ( First..Last ) ) ;

  exception
    when Data_Error =>
      Put_Line ( "Data was invalid -- need to check data source" ) ;
      Put_Line ( "Invalid Data element =>" & Buffer ( Index ) ) ;
      raise ;
  end To_Integer ;


  Data   : integer ;

begin -- b

  Data := To_Integer ( " =123;" ) ;

  Put ( "Data => " ) ;
  Put ( Data ) ;
  New_Line ;


  -- Data_Error is raised

  Data := To_Integer ( "asv456" ) ; 

  Put ( "Data => " ) ;
  Put ( Data ) ;
  New_Line ;

  -- Data_Error is raised

  Data := To_Integer ( " =789.;" ) ; 

  Put ( "Data => " ) ;
  Put ( Data ) ;
  New_Line ;

exception
  when Data_Error =>
      null ;
end b ;

In <d39e1918-0c74-40b5-860d-f8d93181afd2@p59g2000hsd.googlegroups.com>, jedivaughn <jedivaughn14@gmail.com> writes:
>Hi, How is the best way to determine the type of input. I have the
>input coming in through a string but if the contents of the string is
>an integer then I want to convert it to such. This seems like it
>should be very easy to do but I can't seem to find out how to do it
>any where.
>
>
>Thanks,
>
>John

Re: determining input data type

[jedivaughn]

thanks all, got it working just fine with your help

- John