Re: milliseconds and delay until

[Simon Wright <simon@pushface.org>]

Thomas Bruns <newsgroup@donbruno.de> writes:

> how can I handle the until delay statement, too do this: ????
> 
> 
> with ADA.Calendar; use ADA.Calendar;
> 
> procedure ....
> 
> MS : INTEGER; --milliseconds
> 
> begin
> MS:= INTEGER(FLOAT(seconds(clock)) * 1000);
> 
> MS := MS + 100;
> 
> delay until MS; ---???? it is wrong :-( it must be a time type :-( but I
>         -- need the clock from a fixed time and add some milliseconds... 
> --and then the until delay statement....How can I handle this???
> 
> end;

   with Ada.Calendar;
   with Ada.Text_IO;

   procedure Delaying is

      Start : constant Ada.Calendar.Time := Ada.Calendar.Clock;
      Next : Ada.Calendar.Time := Start;
      Millisec : constant Duration := 0.001;

      use type Ada.Calendar.Time;


   begin

      for I in 1 .. 5_000 loop

         Next := Next + Millisec;
         delay until Next;

      end loop;

      Ada.Text_IO.Put_Line (".. that took"
                              & Duration'Image (Ada.Calendar.Clock - Start));

   end Delaying;

The output here (Mandrake 9.1, GNAT 3.16a) is

   .. that took 5.011935000

NB!! on most desktop machines you'll get a minimum actual delay of 10
ms (a tick) or even 2 ticks; what happens, I think, is that many of
the "delay until"s turn out to be delaying until a time that has
already passed, so the program spins until it catches up.