Re: Little Endian -> Big Endian (Ada95 / GNAT)

[Simon Wright <simon@pushface.org>]

jamesamor@hotmail.com (James Amor) writes:

> At present I am writing a tool to create a file which contains various
> extracted ELF symbols. The output data structure, a list of unsigned
> 32's, is to be used as part of an image on a PowerPC target.

If you output source code in your language of choice (C for this part
of the job, even!) you could compile it with the target compiler.

> Problem: As it is compiled on Wintel the tool is producing an output
> in little endian and PowerPC is big endian!
> 
> Question: How do I modify my code to write the output in big endian
> format?

Roughly,

with Ada.Streams;
with Ada.Unchecked_Conversion;
with Interfaces;
with System;

function To_Big_Endian
  (N : Interfaces.Unsigned_32) return Interfaces.Unsigned_32 is
begin
   if System."=" (System.Default_Bit_Order, System.Low_Order_First) then
      declare
         subtype Bytes is Ada.Streams.Stream_Element_Array (1 .. 4);
         function To_Bytes is new Ada.Unchecked_Conversion
           (Interfaces.Unsigned_32, Bytes);
         function From_Bytes is new Ada.Unchecked_Conversion
           (Bytes, Interfaces.Unsigned_32);
         B : constant Bytes := To_Bytes (N);
      begin
         return From_Bytes ((1 => B (4),
                             2 => B (3),
                             3 => B (2),
                             4 => B (1)));
      end;
   else
      return N;
   end if;
end To_Big_Endian;

(compiled but not tested)

-- 
Simon Wright                               100% Ada, no bugs.