Re: Legit Warnings or not

[Robert A Duff <bobduff@shell01.TheWorld.com>]

Anh Vo <anhvofrcaus@gmail.com> writes:

> package Warnings_Legit is
>
>    type Warned_Person (Size : Positive := 10) is -- Warnings issued
> here
>       record
>          Name : String (1 .. Size);
>       end record;
>
>    type Acceptable_Person (Size : Positive) is
>       record
>          Name : String (1 .. Size);
>       end record;
>
> end Warnings_Legit;
>
> The code segment above triggers a warnings message 'creation of
> "Warned_Person" object may raise Storage_Error' at line 3 as marked.
> However, no warnings is issued at line 8. The difference between them
> is default discriminant. I am using GNAT-GPL-2011.

There's a confusing rule in Ada:  If it has defaults, there can be
unconstrained objects of that type (and also constrained ones).
If it doesn't have defaults, then all objects must be constrained.

So if you say "X : Warned_Person;", GNAT will allocate space for
billions of characters (not just 10) because you might assign
a bigger one (like "X := (Size => 1_000_000, Name => Something)").

> Is this warnings legitimate? If yes, why line 8 is OK. Otherwise,
> should it be a bug?

It's not a bug.  An object of type Warned_Person might need huge amounts
of memory, so Storage_Error might well be raised.  It's illegal to say
"X : Acceptable_Person;", so that one doesn't get a warning.

If you want unconstrained objects, use a reasonably-small size, like:

   subtype Name_Length is Natural range 0..1000;

   type Not_Warned_Person (Size : Name_Length := 0) is
      record
         Name : String (1 .. Size);
      end record;

Unconstrained objects of type Not_Warned_Person will then require space
for 1000 characters.

On the other hand, if you don't want unconstrained objects, don't give a
default (as in your Acceptable_Person).

- Bob