Generic child units

Generic child units

[@ 2003-05-13 17:46 UTC (permalink / raw)]

I need some enlightment in this area... Let us suppose that I have two 
generic packages declared in separate files and one is the parent of the 
other:

generic
    type Elem is private;
package Parent is
    type Vector is array (Integer range <>) of Elem;
end Parent;

generic
package Parent.Child is
    subtype Vector2D is Vector (1 .. 2);
end Parent.Child;

How can I instantiate the child package within the declarative region of 
the parent package (as required by RM 10.1(18))?

Rodrigo

Re: Generic child units

[Stephen Leake]

Rodrigo Garc�a <rodrigo.garcia.ARROBA.epfl.ch> writes:

> I need some enlightment in this area... Let us suppose that I have two
> generic packages declared in separate files and one is the parent of
> the other:
> 
> generic
>     type Elem is private;
> package Parent is
>     type Vector is array (Integer range <>) of Elem;
> end Parent;
> 
> generic
> package Parent.Child is
>     subtype Vector2D is Vector (1 .. 2);
> end Parent.Child;
> 
> How can I instantiate the child package 

with Parent.Child;
procedure Foo is
   package Par is new Parent (Elem => Integer);
   package Chi is new Par.Child;
begin
...
end Foo;

Note that the second instantiation is "Par.Child", not "Parent.Child".

> within the declarative region of the parent package (as required by
> RM 10.1(18))?

There is no RM 10.1 (18), at least in the copy I have (came with
GNAT). And I don't understand the rest of the sentence, either. So I
don't know what you mean here.

-- 
-- Stephe

Re: Generic child units

[David C. Hoos]

[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #1: Type: text/plain, Size: 1328 bytes --]

I think the OP meant to say 10.1.1 (18)

"Stephen Leake" <Stephe.Leake@nasa.gov> wrote in message
news:ubry6heul.fsf@nasa.gov...
> Rodrigo Garc�a <rodrigo.garcia.ARROBA.epfl.ch> writes:
>
> > I need some enlightment in this area... Let us suppose that I have two
> > generic packages declared in separate files and one is the parent of
> > the other:
> >
> > generic
> >     type Elem is private;
> > package Parent is
> >     type Vector is array (Integer range <>) of Elem;
> > end Parent;
> >
> > generic
> > package Parent.Child is
> >     subtype Vector2D is Vector (1 .. 2);
> > end Parent.Child;
> >
> > How can I instantiate the child package
>
> with Parent.Child;
> procedure Foo is
>    package Par is new Parent (Elem => Integer);
>    package Chi is new Par.Child;
> begin
> ...
> end Foo;
>
> Note that the second instantiation is "Par.Child", not "Parent.Child".
>
> > within the declarative region of the parent package (as required by
> > RM 10.1(18))?
>
> There is no RM 10.1 (18), at least in the copy I have (came with
> GNAT). And I don't understand the rest of the sentence, either. So I
> don't know what you mean here.
>
> -- 
> -- Stephe
> _______________________________________________
> comp.lang.ada mailing list
> comp.lang.ada@ada.eu.org
> http://ada.eu.org/mailman/listinfo/comp.lang.ada
>

Re: Generic child units

[@ 2003-05-14 7:56 UTC (permalink / raw)]

Stephen Leake wrote:
> Rodrigo Garc�a <rodrigo.garcia.ARROBA.epfl.ch> writes:
> 
> 
>>I need some enlightment in this area... Let us suppose that I have two
>>generic packages declared in separate files and one is the parent of
>>the other:
>>
>>generic
>>    type Elem is private;
>>package Parent is
>>    type Vector is array (Integer range <>) of Elem;
>>end Parent;
>>
>>generic
>>package Parent.Child is
>>    subtype Vector2D is Vector (1 .. 2);
>>end Parent.Child;
>>
>>How can I instantiate the child package 
> 
> 
> with Parent.Child;
> procedure Foo is
>    package Par is new Parent (Elem => Integer);
>    package Chi is new Par.Child;
> begin
> ...
> end Foo;
> 
> Note that the second instantiation is "Par.Child", not "Parent.Child".

   Thanks, that is one of the things I was doing wrong.

>>within the declarative region of the parent package (as required by
>>RM 10.1(18))?
> 
> 
> There is no RM 10.1 (18), at least in the copy I have (came with
> GNAT). And I don't understand the rest of the sentence, either. So I
> don't know what you mean here.

   Sorry, I meant RM 10.1.1 (18) as David C. Hoos has remarked. I still 
do not understand that requirement.

Rodrigo

Re: Generic child units

[Stephen Leake]

Rodrigo Garc�a <rodrigo.garcia.ARROBA.epfl.ch> writes:

> Stephen Leake wrote:
> > Rodrigo Garc�a <rodrigo.garcia.ARROBA.epfl.ch> writes:
> 
> >>within the declarative region of the parent package (as required by
> >>RM 10.1(18))?
> > There is no RM 10.1 (18), at least in the copy I have (came with
> > GNAT). And I don't understand the rest of the sentence, either. So I
> > don't know what you mean here.
> 
>    Sorry, I meant RM 10.1.1 (18) as David C. Hoos has remarked. I
> still do not understand that requirement.

Me either. But my code works anyway :).

-- 
-- Stephe

Re: Generic child units

[Robert A Duff]

Rodrigo Garc�a <rodrigo.garcia.ARROBA.epfl.ch> writes:

> Stephen Leake wrote:
> > Rodrigo Garc�a <rodrigo.garcia.ARROBA.epfl.ch> writes:
> >
> >>I need some enlightment in this area... Let us suppose that I have two
> >>generic packages declared in separate files and one is the parent of
> >>the other:
> >>
> >>generic
> >>    type Elem is private;
> >>package Parent is
> >>    type Vector is array (Integer range <>) of Elem;
> >>end Parent;
> >>
> >>generic
> >>package Parent.Child is
> >>    subtype Vector2D is Vector (1 .. 2);
> >>end Parent.Child;
> >>
> >> How can I instantiate the child package
> > with Parent.Child;
> > procedure Foo is
> >    package Par is new Parent (Elem => Integer);
> >    package Chi is new Par.Child;
> > begin
> > ...
> > end Foo;
> > Note that the second instantiation is "Par.Child", not "Parent.Child".
> 
>    Thanks, that is one of the things I was doing wrong.
> 
> >>within the declarative region of the parent package (as required by
> >>RM 10.1(18))?
> > There is no RM 10.1 (18), at least in the copy I have (came with
> > GNAT). And I don't understand the rest of the sentence, either. So I
> > don't know what you mean here.
> 
>    Sorry, I meant RM 10.1.1 (18) as David C. Hoos has remarked. I still
> do not understand that requirement.

Paragraph 19.b in the AARM explains it.  You are instantiating the child
*outside* the parent generic, so you want to instantiate the child of
the instance of the parent, not the child of the parent.  Make sense?

Here's the AARM text:

 18    A child of a parent generic package shall be instantiated or renamed
 only within the declarative region of the parent generic.

 19    For each declaration or renaming of a generic unit as a child of some
 parent generic package, there is a corresponding declaration nested
 immediately within each instance of the parent. [This declaration is visible
 only within the scope of a with_clause that mentions the child generic unit.]

     19.a  Implementation Note: Within the child, like anything nested in a
           generic unit, one can make up-level references to the current
           instance of its parent, and thereby gain access to the formal
           parameters of the parent, to the types declared in the parent, etc.
           This ``nesting'' model applies even within the generic_formal_part
           of the child, as it does for a generic child of a nongeneric unit.

     19.b  Ramification: Suppose P is a generic library package, and P.C is a
           generic child of P. P.C can be instantiated inside the declarative
           region of P. Outside P, P.C can be mentioned only in a with_clause.
           Conceptually, an instance I of P is a package that has a nested
           generic unit called I.C. Mentioning P.C in a with_clause allows I.C
           to be instantiated. I need not be a library unit, and the
           instantiation of I.C need not be a library unit. If I is a library
           unit, and an instance of I.C is a child of I, then this instance has
           to be called something other than C.

- Bob

Re: Generic child units

[Stephen Leake]

Robert A Duff <bobduff@shell01.TheWorld.com> writes:

> Rodrigo Garc�a <rodrigo.garcia.ARROBA.epfl.ch> writes:
> 
> > Stephen Leake wrote:

> > > with Parent.Child;
> > > procedure Foo is
> > >    package Par is new Parent (Elem => Integer);
> > >    package Chi is new Par.Child;
> > > begin
> > > ...
> > > end Foo;
> > > Note that the second instantiation is "Par.Child", not "Parent.Child".
> > 
> >    Thanks, that is one of the things I was doing wrong.
> > 
> > >>within the declarative region of the parent package (as required by
> > >>RM 10.1(18))?
> > > There is no RM 10.1 (18), at least in the copy I have (came with
> > > GNAT). And I don't understand the rest of the sentence, either. So I
> > > don't know what you mean here.
> > 
> >    Sorry, I meant RM 10.1.1 (18) as David C. Hoos has remarked. I still
> > do not understand that requirement.
> 
> Paragraph 19.b in the AARM explains it.  You are instantiating the child
> *outside* the parent generic, so you want to instantiate the child of
> the instance of the parent, not the child of the parent.  Make sense?
> 
> Here's the AARM text:
> 
>  18    A child of a parent generic package shall be instantiated or renamed
>  only within the declarative region of the parent generic.

But in my code above, Chi is an instantiation of "a child of a parent
generic package", and it is _not_ "within the declarative region of
the parent generic".

>  19 For each declaration or renaming of a generic unit as a child of
>  some parent generic package, there is a corresponding declaration
>  nested immediately within each instance of the parent. [This
>  declaration is visible only within the scope of a with_clause that
>  mentions the child generic unit.]
> 
>      19.a Implementation Note: Within the child, like anything
>      nested in a generic unit, one can make up-level references to
>      the current instance of its parent, and thereby gain access to
>      the formal parameters of the parent, to the types declared in
>      the parent, etc. This ``nesting'' model applies even within the
>      generic_formal_part of the child, as it does for a generic
>      child of a nongeneric unit.
> 
>      19.b Ramification: Suppose P is a generic library package, and
>      P.C is a generic child of P. P.C can be instantiated inside the
>      declarative region of P. Outside P, P.C can be mentioned only
>      in a with_clause. Conceptually, an instance I of P is a package
>      that has a nested generic unit called I.C. 

I see. So I actually instantiated Par.Child (as the code actually says
:), which is _not_ a "child of a generic parent", even though I think
of it that way. 

That makes sense. As is sometimes the case, the ARM is not immediately
clear to us non-lawyers.

>      Mentioning P.C in a with_clause allows I.C to be instantiated.
>      I need not be a library unit, and the instantiation of I.C need
>      not be a library unit. If I is a library unit, and an instance
>      of I.C is a child of I, then this instance has to be called
>      something other than C.
> 
> - Bob

-- 
-- Stephe

Re: Generic child units

[Georg Bauhaus]

Stephen Leake <Stephe.Leake@nasa.gov> wrote:
: Robert A Duff <bobduff@shell01.TheWorld.com> writes:
: 
:> Rodrigo Garc?a <rodrigo.garcia.ARROBA.epfl.ch> writes:
:> 
:> > Stephen Leake wrote:
: 
:> > > with Parent.Child;
:> > > procedure Foo is
:> > >    package Par is new Parent (Elem => Integer);
:> > >    package Chi is new Par.Child;
:> > > begin
:> > > ...
:> > > end Foo;
:> 
:> Here's the AARM text:
:> 
:>  18    A child of a parent generic package shall be instantiated or renamed
:>  only within the declarative region of the parent generic.
: 
: But in my code above, Chi is an instantiation of "a child of a parent
: generic package", and it is _not_ "within the declarative region of
: the parent generic".

Isn't the declarative region of Parent included by "with Parent.Child"? 

-- Georg

Re: Generic child units

[Robert A Duff]

Georg Bauhaus <sb463ba@d2-hrz.uni-duisburg.de> writes:

> Stephen Leake <Stephe.Leake@nasa.gov> wrote:
> : Robert A Duff <bobduff@shell01.TheWorld.com> writes:
> : 
> :> Rodrigo Garc?a <rodrigo.garcia.ARROBA.epfl.ch> writes:
> :> 
> :> > Stephen Leake wrote:
> : 
> :> > > with Parent.Child;
> :> > > procedure Foo is
> :> > >    package Par is new Parent (Elem => Integer);
> :> > >    package Chi is new Par.Child;
> :> > > begin
> :> > > ...
> :> > > end Foo;
> :> 
> :> Here's the AARM text:
> :> 
> :>  18    A child of a parent generic package shall be instantiated or renamed
> :>  only within the declarative region of the parent generic.
> : 
> : But in my code above, Chi is an instantiation of "a child of a parent
> : generic package", and it is _not_ "within the declarative region of
> : the parent generic".

As Stephen Leake said later in his note, the above is wrong.  Chi is a
child of an *instance* of a parent generic (Par).  It is not a child of
Parent.

> Isn't the declarative region of Parent included by "with Parent.Child"? 

No.  The decl region of a thing is the thing and everything nested
within it (including children which are "logically" nested within their
parent).  Foo is not nested within Parent, and "with Parent.Child" does
not change that fact.

- Bob

Re: Generic child units

[Georg Bauhaus]

Robert A Duff <bobduff@shell01.theworld.com> wrote:
: [...]
: 
: No.  The decl region of a thing is the thing and everything nested
: within it (including children which are "logically" nested within their
: parent).  Foo is not nested within Parent, and "with Parent.Child" does
: not change that fact.

Thanks for all the explainations. It helps to read your mundane words
in addition to the RM.


-- Georg

Re: Generic child units

[Robert A Duff]

Stephen Leake <Stephe.Leake@nasa.gov> writes:

> Robert A Duff <bobduff@shell01.TheWorld.com> writes:
> > Here's the AARM text:
> > 
> >  18    A child of a parent generic package shall be instantiated or renamed
> >  only within the declarative region of the parent generic.
> 
> But in my code above, Chi is an instantiation of "a child of a parent
> generic package", and it is _not_ "within the declarative region of
> the parent generic".

No, Chi is not a child of Parent, it is a child of Par, which is a
package, not a generic package.

> I see. So I actually instantiated Par.Child (as the code actually says
> :), which is _not_ a "child of a generic parent", even though I think
> of it that way. 

That's right.  It's very similar to what happens if you had Child
physically nested within Parent.

The way to think of it is, when you instantiate Parent as Par, you get a copy
of all the children, and they are called (for example) Par.Child.
However you can't *see* them unless you say "with Parent.Child".
The  "with Parent.Child" has a somewhat magical effect: it makes *.Child
visible, for all * that are instances of Parent (Par, in your case).

> That makes sense. As is sometimes the case, the ARM is not immediately
> clear to us non-lawyers.

Well, this is one of the more arcane rules in the language.

- Bob

Re: Generic child units

[Georg Bauhaus]

Robert A Duff <bobduff@shell01.theworld.com> wrote:
: Rodrigo Garc?a <rodrigo.garcia.ARROBA.epfl.ch> writes:
: 
:> Stephen Leake wrote:
:> > Rodrigo Garc?a <rodrigo.garcia.ARROBA.epfl.ch> writes:
:> >
:> >>I need some enlightment in this area... Let us suppose that I have two
:> >>generic packages declared in separate files and one is the parent of
:> >>the other:
:> >>
:> >>generic
:> >>    type Elem is private;
:> >>package Parent is
:> >>    type Vector is array (Integer range <>) of Elem;
:> >>end Parent;
:> >>
:> >>generic
:> >>package Parent.Child is
:> >>    subtype Vector2D is Vector (1 .. 2);
:> >>end Parent.Child;
:> >>
:> >> How can I instantiate the child package
:> >>within the declarative region of the parent package (as required by
:> >>RM 10.1[.1](18))?

Am I right that this is supposed to mean, for example,

with Parent.Child;
package body Parent
   package Inst is new Parent.Child;
end Parent;

because the body is part of the declarative region of P,
and there is no circular dependency? (So the instance is *inside* the
parent generic?)

: Paragraph 19.b in the AARM explains it.  You are instantiating the child
: *outside* the parent generic, so you want to instantiate the child of
: the instance of the parent, not the child of the parent.  Make sense?

-- Georg

Re: Generic child units

[Georg Bauhaus]

Stephen Leake <Stephe.Leake@nasa.gov> wrote:
: Rodrigo Garc?a <rodrigo.garcia.ARROBA.epfl.ch> writes:
: 
:> I need some enlightment in this area... Let us suppose that I have two
:> generic packages declared in separate files and one is the parent of
:> the other:
:> 
:> generic
:>     type Elem is private;
:> package Parent is
:>     type Vector is array (Integer range <>) of Elem;
:> end Parent;
:> 
:> generic
:> package Parent.Child is
:>     subtype Vector2D is Vector (1 .. 2);
:> end Parent.Child;
:> 
:> How can I instantiate the child package 
: 
: with Parent.Child;
: procedure Foo is
:   package Par is new Parent (Elem => Integer);
:   package Chi is new Par.Child;
: begin
: ...
: end Foo;
: 
: Note that the second instantiation is "Par.Child", not "Parent.Child".

I find it useful to compare to this variation of the packages, at least
it has shed some light (I think :-/) as far as the instantiation sequence
is concerned:

generic
   type Elem is private;
package Parent is
   type Vector is array (Integer range <>) of Elem;
   
   generic
   package Child is
      subtype Vector2D is Vector (1 .. 2);
   end Child;

end Parent;

So, elsewhere, you can't have an instance of child without an instance
of parent.

But you can have an instance of Child in Parent's body. I don't
know why, exactely, though.

(No wonder that the editors next door tell me that programmers
are funny people :-)


-- Georg

Re: Generic child units

[Robert A Duff]

Georg Bauhaus <sb463ba@d2-hrz.uni-duisburg.de> writes:

> Stephen Leake <Stephe.Leake@nasa.gov> wrote:
> : Rodrigo Garc?a <rodrigo.garcia.ARROBA.epfl.ch> writes:
> : 
> :> I need some enlightment in this area... Let us suppose that I have two
> :> generic packages declared in separate files and one is the parent of
> :> the other:
> :> 
> :> generic
> :>     type Elem is private;
> :> package Parent is
> :>     type Vector is array (Integer range <>) of Elem;
> :> end Parent;
> :> 
> :> generic
> :> package Parent.Child is
> :>     subtype Vector2D is Vector (1 .. 2);
> :> end Parent.Child;
> :> 
> :> How can I instantiate the child package 
> : 
> : with Parent.Child;
> : procedure Foo is
> :   package Par is new Parent (Elem => Integer);
> :   package Chi is new Par.Child;
> : begin
> : ...
> : end Foo;
> : 
> : Note that the second instantiation is "Par.Child", not "Parent.Child".
> 
> I find it useful to compare to this variation of the packages, at least
> it has shed some light (I think :-/) as far as the instantiation sequence
> is concerned:

Yes, the following example shows what's going on.  A child is almost the
same thing as a nested unit.

> generic
>    type Elem is private;
> package Parent is
>    type Vector is array (Integer range <>) of Elem;
>    
>    generic
>    package Child is
>       subtype Vector2D is Vector (1 .. 2);
>    end Child;
> 
> end Parent;
> 
> So, elsewhere, you can't have an instance of child without an instance
> of parent.

Right.  Outside Parent, you can't say "new Parent.Child", but you can
say "new Par.Child" if Par is an instance of Parent.

> But you can have an instance of Child in Parent's body. I don't
> know why, exactely, though.

Because when you're inside the generic, you can see Child.  If you refer
to Parent inside Parent, you are not referring to a generic, you are
referring to a package -- whatever the "current instance" of Parent is.

> (No wonder that the editors next door tell me that programmers
> are funny people :-)

Indeed.

- Bob