Re: functions, packages & characters

["Matthew Heaney" <mheaney@on2.com>]

"Randy Brukardt" <randy@rrsoftware.com> wrote in message
news:u7b1g6cooeo49@corp.supernews.com...
> It is possible to write such a
> Get_Line out of the primitives in Text_IO, but the result would be
> unacceptably slow (because you would have to read a character at a
> time - you can't use Get_Line because you can't tell between the case of
> a line which exactly fills the buffer and a line which is too long and
> does not -- but in the former case, the line terminator is skipped).

This statement is incorrect.  You can test for this case via the predicate:

   if Last < Line'Last then
      --means we've consumed all the input

Which means you can make your input buffer as large as you like.

In general, you should use Get_Line this way:

declare
   Max : constant := 80;           --or whatever
   Line : String (1 .. Max + 1);  --note value of Line'Last
   Last : Natural;
begin
   loop
      Get_Line (Line, Last);
      --do something with Line (Line'First .. Last)
      exit when Last < Line'Last;
   end loop;
end;

You can search comp.lang.ada at google.com for several posts I've written on
this very subject (search for "get_line").


--STX
with Ada.Text_IO;            use Ada.Text_IO;
with Ada.Strings.Unbounded;  use Ada.Strings.Unbounded;

procedure Test_Get_Line is

   Max : constant := 10;
   Line : String (1 .. Max + 1);
   Last : Natural;

   Buffer : Unbounded_String;

begin

   Put ("ready: ");

   loop
      Get_Line (Line, Last);
      Append (Buffer, Line (Line'First .. Last));
      exit when Last < Line'Last;
   end loop;

   Put_Line ("line is '" & To_String (Buffer) & "'");


end Test_Get_Line;