Re: Ada2005

["Matthew Heaney" <mheaney@on2.com>]

"Patrick Hohmeyer" <pi3_1415926536@yahoo.ca> wrote in message
news:K2fS7.15363$Us5.3441773@news20.bellglobal.com...
> In this case I find the C++ definition *way* easier to understand
> than this Chapter 13 babbeling of Ada.

Most of the time you don't have to think about the freezing rules -- if you
try to do something that's not allowed then your compiler will tell you.

This is not unlike the rules for using static_cast vs reinterpret_cast in
C++.  Rather than try to figure out which one to use, just use a
static_cast, and then let the compiler tell you that you need to use a
reinterpret_cast instead.

The basic idea with freezing rules for tagged types is that all the
primitive operations ("virtual methods") for a type have to be known at the
point of derivation.  For example:

package P is
   type T is abstract tagged limited null record;
   procedure Op (O : in out T) is abstract;

   type NT is new T with null record;
   procedure Op (O : in out NT);  --OK

   procedure Another_Op (O : in out T) is abstract;  --primitive op declared
too late
end P;

The declaration of Another_Op for type T comes too late ("after the freezing
point"), because all the primitive operations have to be known at the time
of declaration of type NT.  (This is because they are "implicitly declared"
at the point of declaration of type NT.)

Here's the output of my compiler:

gcc -c -Ic:\ -I- c:\p.ads
p.ads:5:04: warning: no primitive operations for "T" after this line
p.ads:8:14: this primitive operation is declared too late
gnatmake: "c:\p.ads" compilation error


The fix is simple enough:

package P is
   type T is abstract tagged limited null record;
   procedure Op (O : in out T) is abstract;
   procedure Another_Op (O : in out T) is abstract;  --OK

   type NT is new T with null record;
   procedure Op (O : in out NT);  --OK
   procedure Another_Op (O : in out NT); --OK

end P;