How to make a task wait and resume ?

How to make a task wait and resume ?

[reinert]

Hi there,

I have used a protected object to control (from "outside") 
wait/resume of a task. It works, but is it good practise?

Below is an illustration on what I mean. Hope you get it :-)

reinert  

   protected pause1 is
     entry wait1;
     procedure halt1;
     procedure resume1;
   private
     OK : boolean := false;
   end pause1;

   protected body pause1 is

     entry wait1 when OK is
     begin
        null;
     end wait1;

     procedure halt1 is
     begin
       OK := false;
     end halt1;

     procedure resume1 is
     begin
       OK := true;
     end resume1;
   end pause1;

   task body task1 is 
   begin
     loop
       pause1.wait1;
       do_something;
     end loop;
   end task1;

Re: How to make a task wait and resume ?

[Dmitry A. Kazakov]

On 2019-01-17 17:21, reinert wrote:

> I have used a protected object to control (from "outside")
> wait/resume of a task. It works, but is it good practise?

Why not? In other cases you might use a task entry instead of protected 
object.

What you did is a manual reset event. For your case a pulse event might 
work better:

    entry wait1 when OK is
    begin
       OK := False;
    end wait1;

If the pulse event to release several tasks it is a bit more 
complicated. An example is in the Simple Components.

Then there is usually task exit condition involved. So the pattern might be:

    entry wait1 when OK or else Exit_Requested is
    begin
       if Exit_Requested then
          raise End_Error;
       else
          OK := False;
       end if;
    end wait1;

-- 
Regards,
Dmitry A. Kazakov
http://www.dmitry-kazakov.de

Re: How to make a task wait and resume ?

[Randy Brukardt]

"Dmitry A. Kazakov" <mailbox@dmitry-kazakov.de> wrote in message 
news:q1qe0o$1te0$1@gioia.aioe.org...
> On 2019-01-17 17:21, reinert wrote:
>
>> I have used a protected object to control (from "outside")
>> wait/resume of a task. It works, but is it good practise?
>
> Why not? In other cases you might use a task entry instead of protected 
> object.

You could also use the built-in types for that purpose, see D.10, 
Synchronous Task Control.

...
> If the pulse event to release several tasks it is a bit more complicated. 
> An example is in the Simple Components.

 For that, you might want to use a Synchronous Barrier, see D.10.1.

For me, I would try to do this as part of other necessary synchronization, 
using usual task or protected operations. One rarely wants to have a task 
wait in a vacuum. If I had to do it by iteself, however, I'd probably use 
one of the built-in types (have to implement them in Janus/Ada, first, 
though :-).

                          Randy.

Re: How to make a task wait and resume ?

[reinert]

I suspected to be missing something :-)

In my case, a user is normally actively interacting with the actual program
which is about treating a large sequence of images. The user can start/stop 
a task which reads in images upfront to avoid waiting time. If the computer
is weak (small ram) he/she sometimes has to stop the reading (and the program automatically "clean" memory) and probably resume later. Hence the "synchronization" here is not with other tasks.

reinert

torsdag 17. januar 2019 23.28.17 UTC+1 skrev Randy Brukardt følgende:
> "Dmitry A. Kazakov" <mailbox@dmitry-kazakov.de> wrote in message 
> news:q1qe0o$1te0$1@gioia.aioe.org...
> > On 2019-01-17 17:21, reinert wrote:
> >
> >> I have used a protected object to control (from "outside")
> >> wait/resume of a task. It works, but is it good practise?
> >
> > Why not? In other cases you might use a task entry instead of protected 
> > object.
> 
> You could also use the built-in types for that purpose, see D.10, 
> Synchronous Task Control.
> 
> ...
> > If the pulse event to release several tasks it is a bit more complicated. 
> > An example is in the Simple Components.
> 
>  For that, you might want to use a Synchronous Barrier, see D.10.1.
> 
> For me, I would try to do this as part of other necessary synchronization, 
> using usual task or protected operations. One rarely wants to have a task 
> wait in a vacuum. If I had to do it by iteself, however, I'd probably use 
> one of the built-in types (have to implement them in Janus/Ada, first, 
> though :-).
> 
>                           Randy.

Re: How to make a task wait and resume ?

[Dmitry A. Kazakov]

On 2019-01-18 08:59, reinert wrote:
> I suspected to be missing something :-)
> 
> In my case, a user is normally actively interacting with the actual program
> which is about treating a large sequence of images. The user can start/stop
> a task which reads in images upfront to avoid waiting time. If the computer
> is weak (small ram) he/she sometimes has to stop the reading (and the program automatically "clean" memory) and probably resume later. Hence the "synchronization" here is not with other tasks.

This looks more like a classic Ada tasking (AKA monitors):

task body Reader is
    Buffer : Stream_Element_Array (1..Size);
    Last   : Stream_Element_Offset;
    File   : File_Type;
begin
    loop
      -- accept new file, open it
      begin
         loop
            Read (File.Stream, Buffer, Last);
            -- cache portion of file in Buffer (1..Last)
            select
               accept Forget_It;
               -- close file, clean up
               exit;
            else
               null;
            end select;
          end loop;
       exception
          when End_Error =>
             -- close file
    end loop;
end Reader;

-- 
Regards,
Dmitry A. Kazakov
http://www.dmitry-kazakov.de