Re: Using interfaces

["Dmitry A. Kazakov" <mailbox@dmitry-kazakov.de>]

On 2018-06-02 17:20, gautier_niouzes@hotmail.com wrote:

> I am developing a package for displaying some kinds of figures on an open set of devices. I'm trying to use interfaces for that.

This is full multiple dispatch [*]:

    procedure Draw
              (  Shape   : Figure;
                 Surface : in out Device
              )  is abstract;            -- This is not Ada!

Interfaces is no [direct] help.

Usually multiple dispatch is replaced with cascaded dispatch. You first 
dispatch on the figure and then on the device from the implementation of 
Draw:

    type Device is limited interface;
    -- Drawing primitives
    procedure Draw_Filled_Rectangle
              (  Surface : in out Device;
                 Box     : Rectangle;
                 Color   : RGBA_Color
              )  is abstract;
    ...

    type Figure is interface;
    procedure Draw
              (  Shape   : Figure;
                 Surface : in out Device'Class -- No dispatch
              )  is abstract;


    type Filled_Rectangle is new Figure with record
       Position : Box;
       Color    : RGBA_Color;
    end record;
    overriding
       procedure Draw
                 (  Shape   : Filled_Rectangle;
                    Surface : in out Device'Class
                 );

    procedure Draw
              (  Shape   : Filled_Rectangle;
                 Surface : in out Device'Class
              )  is
    begin
       Surface.Draw_Filled_Rectangle (Shape.Position, Shape.Color);
    end Draw;

This is too simple to work always in practice. There is no replacement 
for multiple dispatch.

-------------------------------
* A simplified form of multiple dispatch is multi-method when only one 
types hierarchy is involved, like in arithmetic operations. Full 
multiple dispatch is when different type hierarchies share operations 
like Figure and Device share Draw.

-- 
Regards,
Dmitry A. Kazakov
http://www.dmitry-kazakov.de