Re: [Spark] Arrays of Strings

["Eric G. Miller" <egm2@Jay-Pee-eSs.net>]

In <slrnb95ehu.ob.lutz@taranis.iks-jena.de>, Lutz Donnerhacke wrote:

> In order to implement thin an execve binding, I wonder how to emulate the
> C-Type "char const * const x []". Any bright ideas?

Errm, my local definition of execve looks like:

int execve(const char *filename, 
           char *const argv [], char *const envp[]);

What'd the const pointer be for?  Even if your definition had such, that'd
be a burden upon the C function, but shouldn't much affect the Ada side of
things.

Try the following out (rename "/tmp/hello" as appropriate)...

-- executor.ads
with Interfaces.C.Strings;

package Executor is

   package C renames Interfaces.C;

   function Execve (Filename : C.Strings.Chars_Ptr;
                    Argv     : C.Strings.Chars_Ptr_Array;
                    Envp     : C.Strings.Chars_Ptr_Array) return C.Int;

   pragma Import (Convention => C,
                  Entity => Execve,
                  External_Name => "execve");

end Executor;


-- try_exec.adb
with Ada.Text_Io;
use Ada.Text_Io;
with Executor;
with Interfaces.C.Strings;

procedure Try_Exec
is
   package C renames Interfaces.C;

   Argv : C.Strings.Chars_Ptr_Array :=
     (C.Strings.New_String("John"),
      C.Strings.New_String("Bill"),
      C.Strings.New_String("Bob"),
      C.Strings.Null_Ptr);

   -- GNAT says there can't only be one??
   Envp : C.Strings.Chars_Ptr_Array :=
     (C.Strings.Null_Ptr, C.Strings.Null_Ptr);

   FileName : C.Strings.Chars_Ptr :=
     C.Strings.New_String("/tmp/hello");

   Status : C.Int;

begin

   Status := Executor.Execve(FileName => FileName,
                    Argv => Argv, Envp => Envp);

   -- Got here?
   Put_Line ("That didn't work! Got " & C.Int'Image(Status));

end Try_Exec;

-- hello.c
#include <stdio.h>

int main (int argc, char *argv[])
{
  int i;

  for (i = 0; i < argc; ++i) {
    printf ("Hello %s!\n", argv[i]);
  }

  return 0;
}

-- 
echo ">gra.fcw@2ztr< eryyvZ .T pveR" | rot13 | reverse