Re: Generic Package

[Dmitry A. Kazakov <mailbox@dmitry-kazakov.de>]

On 2 Dec 2003 15:15:45 -0800, ratsonjaniv@hotmail.com (Mr. J.) wrote:

>Hi,
>I have this code :
>
>*********************************************************************
>generic
>    type Language is array (Positive range<>) of Character;
>    type States is array (Positive range <>) of Integer;
>
>    package Automat_Producer is
>
>    type StatesFunctions is array(Character,Integer) of Integer;
>
>    procedure Init(Q0:Integer);
>    procedure Change_State(C:Character);
>    function Is_Final_State return Boolean;
>
>private
>
>    Statesarr: Statesfunctions;
>    Currentstate : Integer;
>    FinalStates : States;
>
>end Automat_Producer;
>*********************************************************************
>
>I have few Questions:
>
>How and when do I set the sizes of the generic types arrays?

Upon instantiation.

>The compiler need to know the size of the FinalStates:States member, I
>will know it only during run-time, How do I do it?
>I think I need somthing similiar to C++'s Constructor.

Not necessariliy. You have to constrain the variable States. There are
many ways to do what you need.

For example

1. you can pass the array bounds as the parameters:

generic
   Number_Of_Final_States : Positive;
   type States is array (Positive range <>) of Integer;
   ... -- Other generic formal parameters
package Automat_Producer is
   ... -- Public interface
private
   FinalStates : States (1..Number_Of_Final_States);
   ... -- Other private things
end Automat_Producer;

So you could instantiate Automat_Producer with a desired number of
states:

package My_Producer is
   new Automat_Producer (Number_Of_Final_States => 10, ...);

2. you can pass the set of final states as a parameter:

generic
   type States is array (Positive range <>) of Integer;
   FinalStates : States;
   ... -- Other generic formal parameters
package Automat_Producer is
   ... -- Public interface
private
   -- Do not need a list of final states it is a parameter now
   ... -- Other private things
end Automat_Producer;

3. you could make the states an enumeration type with a domain set
separated into final and non-final states:

generic   
   type State is (<>);
   First_Final_State : State;
   Last_Final_State : State;
   ... -- Other generic formal parameters
package Automat_Producer is
   ... -- Public interface
private
   -- Do not need a list of final states, a state is tested
   -- as if X in First_Final_State..Last_Final_State then
   --
   ... -- Other private things
end Automat_Producer;

4. you could provide a tester:

generic   
   type State is (<>);
   with function Is_Final (This : State) return Boolean;
   ... -- Other generic formal parameters
package Automat_Producer is
   ... -- Public interface
private
   -- Do not need a list of final states, a state is tested
   -- using Is_Final.
   ... -- Other private things
end Automat_Producer;

--
Regards,
Dmitry Kazakov
http://www.dmitry-kazakov.de