Re: Win32. Task or CreateThread

["Dmitry A. Kazakov" <mailbox@dmitry-kazakov.de>]

On 2016-08-05 06:25, George J wrote:

> Hi All! I have a question for Gtk.Main.Routers, that i can't understand.
> I have next:
>
> type My_Record is
> record
> .......
> end record
>
> type My_Record_Access is access all My_Record;
>
> Test_Record_Access : My_Record_Access;
>
> package Cb_Request is new Gtk.Main.Router.Generic_Callback_Request(User_Data => My_Record);
>
>    task type My_Task is  -- works well
>       entry Start;
>    end My_Task;
>
>    task body My_Task is
>    begin
>       accept Start;
>
>       Cb_Request.Request(Some_Proc'Access,Test_Record_Access); -- all ok
>
>    end My_Task;
>
> But I need to send parameter to discriminant like this
> .. in some proc
> Some_Task.Start(Test_Record_Access)
>
> and decl:
>
>    task type My_Task is  -- works bad
>       entry Start(Rec_Acc:My_Record_Access);
>    end My_Task;
>
>    task body My_Task is
>    begin
>       accept Start(Rec_Acc:My_Record_Access) do
>          Cb_Request.Request(Some_Proc'Access,Rec_Acc); -- "freezed"
>       end Start;
>    end My_Task;

You have a deadlock here. The main task, that runs messages loop, 
engages the rendezvous Start with My_Task. During the rendezvous My_Task 
makes a request back which waits for main task timer callback to be 
serviced. That never happens because the main task sits in the rendezvous.

What you can do is to move the request out of the rendezvous letting the 
caller (main) task go:

    task body My_Task is
       Data : My_Record_Access;
    begin
       accept Start (Rec_Acc : My_Record_Access) do
          Data := Rec_Acc; -- Copy the parameter
       end Start; -- Let go
       Cb_Request.Request (Some_Proc'Access, Data); -- Ask back
    end My_Task;

-- 
Regards,
Dmitry A. Kazakov
http://www.dmitry-kazakov.de