oo problem help please

oo problem help please

[shoko]

what is wrong with the following code:

----car.ads----
package car is
  --car class --
  type car is tagged private; 
  type car_ptr is access all car'class;
  
  --car methods --
  procedure set_name(name:String;this:in out car);
  function  get_name(this:car) return string;
  
 private
     type car is tagged 
     record
         name:String(1..256);
     end record;
  
   
end car;
---car.adb---
package body car is
  procedure set_name(name:String;This:in out car)is
  begin 
     this.name:=name;
  end set_name;
  
  function  get_name(this:car) return string is
  begin 
     return this.name; 
  end get_name;  
end car;
----transport.ads-----
with car;

package transport is
   type transport_rec is new car.car with private;
   type transport_Ptr is access all transport_rec'Class;

   function init_transport(maximum_speed:positive) return transport_Ptr;
   
   private
     type transport_rec is new  car.car with null record;
         
end transport;

-----transport.adb----
package body transport is
   function init_transport(maximum_speed:positive)return transport_Ptr is
        This: transport_Ptr;
   begin
      This:= new transport_Rec;
         
      return this;
   end init_transport;
  

end transport;

----------bus.ads---
with transport;

package bus is
   type bus is new transport.transport_rec with private ;
   type bus_Ptr is access all bus'Class;
   function initbus(name:string) return bus_Ptr;
   private
      type bus is new transport.transport_rec with null record;
end bus;    

---------bus.adb--------
package body bus is
   function initbus(name:String) return bus_Ptr is
       This: bus_ptr;
   begin
      This := new bus;
      set_name(name,this.all);   <--  CONSTRAINT ERROR
      
      return this;
   end initbus;

end bus;
------------------------------
and finally

--------main.adb--------------

with car;use car;
with bus;use bus;


procedure main is
   cars:array(1..2) of car_ptr;
   new_bus:bus_ptr;
   
  
begin
 
     cars(1) := car_ptr(initbus("mercedes"));
  
end main;


the problem is that i get constraint error when the code is executed
why???

Re: oo problem help please

[Marius Amado Alves]

On Mon, 2003-12-08 at 19:49, shoko wrote:
> what is wrong with the following code:
> ...
>      type car is tagged 
>      record
>          name:String(1..256);
>      end record;
> ...
>   procedure set_name(name:String;This:in out car)is
>   begin 
>      this.name:=name;

My guess is this last line.

> ... the problem is that i get constraint error when the code is executed
> why???

Ditto.

Possible fixes:

- pad (or trim) to 256 before assigning;

- make sure the target is initialized to spaces (say), and that the
source is no longer than the target, and then write This.Name (1 ..
Target'Length) := Name;

- redefine the component to be a pointer to string, then write This.Name
:= new String' (Name);

Re: oo problem help please

[Martin Krischik]

shoko wrote:

> what is wrong with the following code:

Wrong choices

> ----car.ads----
> package car is
>   --car class --
>   type car is tagged private;
>   type car_ptr is access all car'class;
>   
>   --car methods --
>   procedure set_name(name:String;this:in out car);
>   function  get_name(this:car) return string;
>   
>  private
>      type car is tagged
>      record
>          name:String(1..256);
>      end record;
>   

I don't belive that every name should be 256 characters long.

> begin
>ￜￜￜￜￜcars(1)ￜ:=ￜcar_ptr(initbus("mercedes"));
ￜￜ
Yes "mercedes" is not 256 Characters. You should take a look at

http://www.adaic.org/standards/95lrm/html/RM-A-4-4.html
http://www.adaic.org/standards/95lrm/html/RM-A-4-5.html

Fact is that you got the wrong type of string. If there is a max lenght
(like you want to store your vechicles in a database) then use
Ada.Strings.Bounded if not use Ada.Strings.Unbounded.

Or if the name is constant use a discriminant:

type car (
    Name_Lenght : Positive)
is tagged record
    name : String(1 .. Name_Lenght);
end record;

With Regards

Martin

-- 
mailto://krischik@users.sourceforge.net
http://adacl.sourceforge.net

Re: oo problem help please

[Martin Krischik]

Marius Amado Alves wrote:

> - redefine the component to be a pointer to string, then write This.Name
> := new String' (Name);

There are better ways then the use Pointers. Beginners are better of using
Ada.Strings.Unbounded (http://www.adaic.org/standards/95lrm/html
RM-A-4-5.html) and think about the advanced techniques laster.

I don't think he is planning for embedded software where
Ada.Strings.Unbounded might be a problem.

With Regards

Martin

-- 
mailto://krischik@users.sourceforge.net
http://adacl.sourceforge.net