Re: output of enumeration types

[Stephen Leake <stephen_leake@acm.org>]

"Staszek Goldstein" <goldstei@math.uni.lodz.pl> writes:

> Maybe I should make myself clearer. I find it very inelegant to write 
> something like:
> function conversion(rm: roman_digit) return character is
> begin
>     case rm is
>         when 'I' => retunrn 'I';
>         when 'V'=>retrun 'V';
> and so on, and then to construct a routine for conversion of a roman number 
> to a string using the function. Is there any better way? 

Use a constant array:

with Ada.Text_Io;
procedure Roman
is
   type Roman_Digit is ('I','V','X','L','C','D','M');
   type Roman_Number is array (positive range <>) of roman_digit;

   Roman_Character_Map : constant array (Roman_Digit) of Character :=
     ('I' => 'I',
      'V' => 'V',
      'X' => 'X',
      'L' => 'L',
      'C' => 'C',
      'D' => 'D',
      'M' => 'M');

   function To_String (Item : in Roman_Number) return String
   is
      Result : String (Item'Range);
   begin
      for I in Item'Range loop
         Result (I) := Roman_Character_Map (Item (I));
      end loop;
      return Result;
   end To_String;

   A : Roman_Number := "MMV";
begin
   Ada.Text_Io.Put_Line ("MMV => " & To_String (A));
end Roman;

-- 
-- Stephe