Re: Computer Language Shootout

["David C. Hoos" <david.c.hoos.sr@ada95.com>]

Interesting... It looks like a GNAT bug to me.  With 3.15p, the message
about line 8 occurs twice, apparently meaning that it couldn't decide on a
call to Get_Line with or without an actual parameter.

I say this, because without the default parameter declaration (i.e., always
requiring a parameter, there is no ambiguity;

Also, changing your conditional doce to the following also removes the
ambiguity, as far as GNAT is concerned:

       if Last < Buffer'Last then
          return Buffer(1..Last);
       else
          declare
             Temp : String := Get_Line (2*Buffer_Size);
          begin
             return Buffer & Temp;
          end;
       end if;

This should be reported to GNAT as a bug.

----- Original Message ----- 
From: "Robert Spooner" <rls19@psu.edu>
Newsgroups: comp.lang.ada
To: <comp.lang.ada@ada.eu.org>
Sent: Friday, July 18, 2003 1:04 PM
Subject: Re: Computer Language Shootout


> Robert A Duff wrote:
> > "Jean-Pierre Rosen" <rosen@adalog.fr> writes:
> >
> >
> >>This one reads a line with no length limit:
> >>
> >>function Get_Line return String is
> >>   Buffer : String (1..500); -- or whatever
> >>   Last : Natural;
> >>begin
> >>   Get_Line (Buffer, Last);
> >>   if Last < Buffer'Last then
> >>      return Buffer (1..Last);
> >>   else
> >>      return Buffer & Get_Line;
> >>   end if;
> >>end Get_Line;
> >>
> >>In most cases, there will be only one call, while having no upper limit.
> >>The size of the buffer is just a matter of optimization.
> >
> >
> > This is a nice trick, but I suggest you grow the buffer exponentially,
> > in case lines are very long.  Like, double it on each recursion level.
> >
> > Too bad this was not included in Text_IO itself.  It would save
> > beginners a lot of trouble.  Sigh.
> >
> > - Bob
> I tried this using the following program and gnat version 3.13p on
> windows professional 2000 with the following result:
>
> with Ada.Text_IO;
>
> procedure No_String_Length_Limit_Test is
>
>     package Tio renames Ada.Text_IO;
>
>
>     function Get_Line (Buffer_Size : Positive := 1) return String is
>        Buffer : String (1..Buffer_Size);
>        Last   : Natural;
>     begin
>        Tio.Get_Line (Buffer, Last);
>        if Last < Buffer'Last then
>           return Buffer(1..Last);
>        else
>           return Buffer & Get_Line (2*Buffer_Size);
>        end if;
>     end Get_Line;
>
>
> begin -- No_String_Length_Limit_Test
>
>     loop
>        Tio.Put ("Enter a message, <Return> to exit: ");
>        declare
>           The_Message : String := Get_Line;
>        begin
>           exit when The_Message'Length = 0;
>           Tio.Put_Line ("The message is " & The_Message);
>        end;
>     end loop;
>
> end No_String_Length_Limit_Test;
>
> no_string_length_limit_test.adb:16:26: ambiguous operand for concatenation
> no_string_length_limit_test.adb:16:26: possible interpretation at line 8
> Done--error detected.
>
> Can someone tell me why the operand is ambiguous?
>
> Bob
> -- 
>                              Robert L. Spooner
>                       Registered Professional Engineer
>                         Associate Research Engineer
>                    Intelligent Control Systems Department
>
>           Applied Research Laboratory        Phone: (814) 863-4120
>           The Pennsylvania State University  FAX:   (814) 863-7841
>           P. O. Box 30
>           State College, PA 16804-0030       rls19@psu.edu
>
> _______________________________________________
> comp.lang.ada mailing list
> comp.lang.ada@ada.eu.org
> http://ada.eu.org/mailman/listinfo/comp.lang.ada
>