Re: Constructor for a class with a task defined

[Simon Wright <simon@pushface.org>]

"Rego, P." <pvrego@gmail.com> writes:

> I'm trying to implement a Constructor method for a class which have a
> task type pointed to the class, so
>
> in spec:
> type Small_Class;
>
> task type My_Task_Type (This_Small_Class : access Small_Class);
>
> type Small_Class is tagged limited
>       record
>          My_Task      : My_Task_Type (Small_Class'Access);
>       end record;
>
> and in body:
>
> function Construct return access Small_Class is
>    begin
>       return new Small_Class'(My_Task => ???????);
> end Construct;
>
>
> So, how can I do it?

You don't need to do anything.

The code below works (I realise now that I've changed the names, sorry
about that):

   package Small_Class is
      type Instance is limited private;
      type Instance_P is access all Instance;
      function Create (Index : Integer) return Instance_P;
      procedure Start (This : Instance_P);
   private
      task type T (This : not null access Instance) is
         entry Start;
      end T;
      type Instance is limited record
         The_T : T (This => Instance'Access);
         Index : Integer := 0;
      end record;
   end Small_Class;

   with Ada.Text_IO; use Ada.Text_IO;
   package body Small_Class is

      task body T is
      begin
         accept Start;
         Put_Line ("T (" & Integer'Image (This.Index) & " ) started.");
      end T;

      function Create (Index : Integer) return Instance_P
      is
         Result : Instance_P := new Instance;
      begin
         Result.Index := Index;
         return Result;
      end Create;

      procedure Start (This : Instance_P) is
      begin
         This.The_T.Start;
      end Start;

   end Small_Class;

   with Small_Class;
   with Ada.Text_IO; use Ada.Text_IO;
   procedure Small_Class_Test is
      H : Small_Class.Instance_P;
   begin
      H := Small_Class.Create (42);
      Put_Line ("waiting ...");
      delay 1.0;
      Put_Line ("starting ...");
      Small_Class.Start (H);
   end Small_Class_Test;

As others have suggested, you could try compiling using GNAT GPL 2011
and -gnat12 and changing Create to

   function Create (Index : Integer) return Instance_P
   is
   begin
      return new Instance'(Index => Index, others => <>);
   end Create;

but when I tried it I got a bug box (which I shall report directly!)