Ada.Numerics.Long_Real_Arrays

Ada.Numerics.Long_Real_Arrays

[hnptz]

Hi,

these are my definitions:

with Ada.Numerics.Long_Real_Arrays; use Ada.Numerics.Long_Real_Arrays;
package nm is

Np : Positive;
Type R_Vector is new Real_Vector (1..Np);
Type R_Matrix is array (Positive range <>) of R_Vector;

procedure nm1 (P : in out R_Matrix);

end nm;

-- definition of procedure nm1 in package body nm done.

now in procedure test_nm.adb (only definitions):

Np : Positive := 2;
Mp : Positive := Np+1;

24  P : R_Matrix(1..Mp) := ((x,x),(y,y),(z,z));

no "build all" error or warning

result when running:

raised CONSTRAINT_ERROR : test_nm.adb: 24 length check failed.

Can you help?

Re: Ada.Numerics.Long_Real_Arrays

[Simon Wright]

hnptz@yahoo.de writes:

> with Ada.Numerics.Long_Real_Arrays; use Ada.Numerics.Long_Real_Arrays;
> package nm is
>
> Np : Positive;

So what value does Np have at this point?

> Type R_Vector is new Real_Vector (1..Np);

Np here will have whatever value it has been assigned by the compiler;
on my system, it was 0 (which isn't valid for Positive, but I expect the
compiler is allowed to make an undefined value whatver is convenient for
it).

> Type R_Matrix is array (Positive range <>) of R_Vector;
>
> procedure nm1 (P : in out R_Matrix);
>
> end nm;

> now in procedure test_nm.adb (only definitions):
>
> Np : Positive := 2;

This is a local declaration which hides Nm.Np (even if you "use Nm;");
setting a value here has no effect on Nm.Np.

> Mp : Positive := Np+1;
>
> 24  P : R_Matrix(1..Mp) := ((x,x),(y,y),(z,z));
>
> no "build all" error or warning

Because it's quite legal to have an array with index range 1 .. 0 -- it
just means it's empty (zero length).

> result when running:
>
> raised CONSTRAINT_ERROR : test_nm.adb: 24 length check failed.

Why not use Ada.Numerics.Long_Real_Arrays.Real_Matrix?

Re: Ada.Numerics.Long_Real_Arrays

[hnptz]

On Wednesday, January 25, 2017 at 1:25:18 PM UTC+1, hn...@yahoo.de wrote:
> Hi,
> 
> these are my definitions:
> 
> with Ada.Numerics.Long_Real_Arrays; use Ada.Numerics.Long_Real_Arrays;
> package nm is
> 
> Np : Positive;
> Type R_Vector is new Real_Vector (1..Np);
> Type R_Matrix is array (Positive range <>) of R_Vector;
> 
> procedure nm1 (P : in out R_Matrix);
> 
> end nm;
> 
> -- definition of procedure nm1 in package body nm done.
> 
> now in procedure test_nm.adb (only definitions):
> 
> Np : Positive := 2;
> Mp : Positive := Np+1;
> 
> 24  P : R_Matrix(1..Mp) := ((x,x),(y,y),(z,z));
> 
> no "build all" error or warning
> 
> result when running:
> 
> raised CONSTRAINT_ERROR : test_nm.adb: 24 length check failed.
> 
> Can you help?

First, I want to keep the length of P open until I fix it in test_nm.adb. The length of R_Vector is always Mp-1.
Second, I want to use the builtin Real_Vector arithmetic, that I do not have to resort to loops. Using Real_Matrix definitions won't allow it, as slices of n-dimensional arrays are not possible.

Re: Ada.Numerics.Long_Real_Arrays

[Simon Wright]

hnptz@yahoo.de writes:

> On Wednesday, January 25, 2017 at 1:25:18 PM UTC+1, hn...@yahoo.de wrote:
>> Hi,
>> 
>> these are my definitions:
>> 
>> with Ada.Numerics.Long_Real_Arrays; use Ada.Numerics.Long_Real_Arrays;
>> package nm is
>> 
>> Np : Positive;
>> Type R_Vector is new Real_Vector (1..Np);
>> Type R_Matrix is array (Positive range <>) of R_Vector;
>> 
>> procedure nm1 (P : in out R_Matrix);
>> 
>> end nm;

> First, I want to keep the length of P open until I fix it in
> test_nm.adb. The length of R_Vector is always Mp-1.  Second, I want to
> use the builtin Real_Vector arithmetic, that I do not have to resort
> to loops. Using Real_Matrix definitions won't allow it, as slices of
> n-dimensional arrays are not possible.

You could try a generic?

with Ada.Numerics.Long_Real_Arrays;
generic
   Rows : Positive;
package Nm_G is
   subtype R_Vector
     is Ada.Numerics.Long_Real_Arrays.Real_Vector (1 .. Rows - 1);
   type R_Matrix is array (1 .. Rows) of R_Vector;
end Nm_G;

with Ada.Text_Io; use Ada.Text_Io;
with Nm_G;
procedure Nm_Test is
   package Nm is new Nm_G (Rows => 3);
   use Nm;
   P : R_Matrix := ((42.0, 42.0), (43.0, 43.0), (44.0, 44.0));
   V : R_Vector := P (P'Last);
begin
   Put_Line ("v: " & V (V'First)'Img & ", " & V (V'Last)'Img);
end Nm_Test;

Re: Ada.Numerics.Long_Real_Arrays

[hnptz]

On Wednesday, January 25, 2017 at 1:25:18 PM UTC+1, hn...@yahoo.de wrote:
> Hi,
> 
> these are my definitions:
> 
> with Ada.Numerics.Long_Real_Arrays; use Ada.Numerics.Long_Real_Arrays;
> package nm is
> 
> Np : Positive;
> Type R_Vector is new Real_Vector (1..Np);
> Type R_Matrix is array (Positive range <>) of R_Vector;
> 
> procedure nm1 (P : in out R_Matrix);
> 
> end nm;
> 
> -- definition of procedure nm1 in package body nm done.
> 
> now in procedure test_nm.adb (only definitions):
> 
> Np : Positive := 2;
> Mp : Positive := Np+1;
> 
> 24  P : R_Matrix(1..Mp) := ((x,x),(y,y),(z,z));
> 
> no "build all" error or warning
> 
> result when running:
> 
> raised CONSTRAINT_ERROR : test_nm.adb: 24 length check failed.
> 
> Can you help?

I was hesitating to use generic in this example, as it produces more code. I'm using generic procedure with function definition and supplementary instantiation anyway, and running out of sensible names is another issue concerning transparency and elegance. However, thanks for definitely pointing to a generic solution.

Re: Ada.Numerics.Long_Real_Arrays

[hnptz]

On Wednesday, January 25, 2017 at 1:25:18 PM UTC+1, hn...@yahoo.de wrote:
> Hi,
> 
> these are my definitions:
> 
> with Ada.Numerics.Long_Real_Arrays; use Ada.Numerics.Long_Real_Arrays;
> package nm is
> 
> Np : Positive;
> Type R_Vector is new Real_Vector (1..Np);
> Type R_Matrix is array (Positive range <>) of R_Vector;
> 
> procedure nm1 (P : in out R_Matrix);
> 
> end nm;
> 
> -- definition of procedure nm1 in package body nm done.
> 
> now in procedure test_nm.adb (only definitions):
> 
> Np : Positive := 2;
> Mp : Positive := Np+1;
> 
> 24  P : R_Matrix(1..Mp) := ((x,x),(y,y),(z,z));
> 
> no "build all" error or warning
> 
> result when running:
> 
> raised CONSTRAINT_ERROR : test_nm.adb: 24 length check failed.
> 
> Can you help?

I have conducted the following:

nm_G.ads -- generic package as suggested -- value of Np not known

nm.ads  with nm_g
package nm is -- Np still not known
...
generic
with function f(R : R_Vector) return Long_Float;
procedure fnm(P : in out R_Matrix); -- R_Matrix is not visible
...
end nm;

nm.adb
package body nm is --Np still not known
Procedure fnm(P : in out R_Matrix) is
...
end fnm; -- R_Matrix not visible
end nm;

test_nm.adb
procedure test_nm is
-- Np known
-- instantiation of R_Matrix not possible as nm.ads has errors
Definitions for f;
call for fem;
end test_nm;

I have nm_G.ads, nm.ads, nm.adb and test_nm.adb, and I want to specify Np in test_nm.adb only, How can it be made possible ?

Re: Ada.Numerics.Long_Real_Arrays

[Simon Wright]

hnptz@yahoo.de writes:

> I have nm_G.ads, nm.ads, nm.adb and test_nm.adb, and I want to specify
> Np in test_nm.adb only, How can it be made possible ?

The thing is, you've supplied code examples that wouldn't even begin to
compile because you've cut out so much and replaced with
english-language text. The result is that we have no real idea what
you're talking about.

Re: Ada.Numerics.Long_Real_Arrays

[Simon Wright]

Also, it would help if you could "reply" to the immediate message rather
than to your original head message (use the leftward-curving arrow at the
top right of the immediate message). That way we can see how the thread
fits together.

Re: Ada.Numerics.Long_Real_Arrays

[Simon Wright]

Simon Wright <simon.john.wright@gmail.com> writes:

> That way we can see how the thread fits together.

At least, those of us who use newsreaders capable of showing a threaded
view! (does anyone know how to get Google Groups to show a tree view of
threads?)

Re: Ada.Numerics.Long_Real_Arrays

[hnptz]

On Thursday, January 26, 2017 at 8:47:07 AM UTC+1, Simon Wright wrote:
> hnptz@yahoo.de writes:
> 
> > I have nm_G.ads, nm.ads, nm.adb and test_nm.adb, and I want to specify
> > Np in test_nm.adb only, How can it be made possible ?
> 
> The thing is, you've supplied code examples that wouldn't even begin to
> compile because you've cut out so much and replaced with
> english-language text. The result is that we have no real idea what
> you're talking about.

I have conducted four files:

1. file nm_g.ads:

with Ada.Numerics.Long_Real_Arrays; 
generic 
  Np : Positive; 
package Nm_G is 
   subtype R_Vector 
     is Ada.Numerics.Long_Real_Arrays.Real_Vector (1 .. Np); 
   type R_Matrix is array (1 ..Np+1) of R_Vector; 
end Nm_G; 

2. file nm.ads:

with Ada.Numerics.Long_Real_Arrays; use Ada.Numerics.Long_Real_Arrays;
with nm_g;
package nm is
…
generic
with function f(R : R_Vector) return Long_Float;
procedure fnm ( P : in out R_Matrix);
…
end nm;

result: R_Matrix is not visible. But I don’t know Np at this moment.

3. file nm.adb:

package body nm is
…
procedure fnm ( P : in out R_Matrix) is
…
end fnm;
end nm;

result: R_Matrix is not visible. But I still don’t know Nt at this moment.

4. file test_nm.adb

with nm; use nm;
procedure test_nm is
Np : Positive := 2;
P : R_Matrix := ((1.0,2.0),(3.0,4.0),(5.0,6.0));
begin
fnm(P);
end test_nm;

result: cannot work

I admit this is only the way, I would like to set up the project. However, using an array of Real_Vectors may require a different approach.

Re: Ada.Numerics.Long_Real_Arrays

[Simon Wright]

This will compile, and preserve visibility of the underlying Vectors.
I'm not sure whether one could get something less clumsy by using
Ada.Containers.Indefinite_Vectors to hold the R_Vectors.

with Ada.Numerics.Long_Real_Arrays;
generic
   Np : Positive;
package Nm_G is
   subtype R_Vector
     is Ada.Numerics.Long_Real_Arrays.Real_Vector (1 .. Np);
   type R_Matrix is array (1 .. Np + 1) of R_Vector;
end Nm_G;

with Nm_G;
package Nm is
   --  I assume there's more than just Fnm here; if not, Fnm could be a
   --  library-level generic subprogram.
   --
   --  Of course, if there _is_ more than just Fnm, it's likely the
   --  other components will also need to know which instantiation of
   --  Nm_G they have to deal with, and the 'with package' bit would
   --  need to be placed on the Nm (which itself has to be generic).
   generic
      --  This generic needs to know which instantiation of Nm_G it is
      --  to deal with.
      with package Nm_I is new Nm_G (<>);
      --  Now we know what type the parameter of the actual F has to
      --  be.
      with function F (R : Nm_I.R_Vector) return Long_Float;
   procedure Fnm (P : in out Nm_I.R_Matrix);
end Nm;

package body Nm is
   procedure Fnm (P : in out Nm_I.R_Matrix) is
   begin
      null;
   end Fnm;
end Nm;

with Nm;
with Nm_G;
procedure Test_Nm is
   package Nm_Inst is new Nm_G (Np => 2);
   function Actual_F (R : Nm_Inst.R_Vector) return Long_Float is (42.0);
   procedure Actual_Fnm is new Nm.Fnm (Nm_I => Nm_Inst,
                                       F    => Actual_F);
   P : Nm_Inst.R_Matrix := ((1.0, 2.0), (3.0, 4.0), (5.0, 6.0));
begin
   Actual_Fnm (P);
end Test_Nm;

Re: Ada.Numerics.Long_Real_Arrays

[Simon Wright]

Simon Wright <simon@pushface.org> writes:

> I'm not sure whether one could get something less clumsy by using
> Ada.Containers.Indefinite_Vectors to hold the R_Vectors.

with Ada.Containers.Indefinite_Vectors;
with Ada.Numerics.Long_Real_Arrays;
package Nmc is
   package Matrices is new Ada.Containers.Indefinite_Vectors
     (Positive,
      Ada.Numerics.Long_Real_Arrays.Real_Vector,
      "=" => Ada.Numerics.Long_Real_Arrays."=");
   subtype Matrix is Matrices.Vector;
end Nmc;

with Nmc;
procedure Test_Nmc is
   M : Nmc.Matrix;
begin
   M (1) := (1.0, 2.0);
   M (2) := (3.0, 4.0);
   M (3) := (5.0, 6.0);
end Test_Nmc;

Re: Ada.Numerics.Long_Real_Arrays

[hnptz]

> Hi,
> 
> these are my definitions:
> 
> with Ada.Numerics.Long_Real_Arrays; use Ada.Numerics.Long_Real_Arrays;
> package nm is
> 
> Np : Positive;
> Type R_Vector is new Real_Vector (1..Np);
> Type R_Matrix is array (Positive range <>) of R_Vector;
> 
> procedure nm1 (P : in out R_Matrix);
> 
> end nm;
> 
> -- definition of procedure nm1 in package body nm done.
> 
> now in procedure test_nm.adb (only definitions):
> 
> Np : Positive := 2;
> Mp : Positive := Np+1;
> 
> 24  P : R_Matrix(1..Mp) := ((x,x),(y,y),(z,z));
> 
> no "build all" error or warning
> 
> result when running:
> 
> raised CONSTRAINT_ERROR : test_nm.adb: 24 length check failed.
> 
> Can you help?


On January 25. Simon Wright wrote:

You could try a generic? 

with Ada.Numerics.Long_Real_Arrays; 
generic 
   Rows : Positive; 
package Nm_G is 
   subtype R_Vector 
     is Ada.Numerics.Long_Real_Arrays.Real_Vector (1 .. Rows - 1); 
   type R_Matrix is array (1 .. Rows) of R_Vector; 
end Nm_G; 

with Ada.Text_Io; use Ada.Text_Io; 
with Nm_G; 
procedure Nm_Test is 
   package Nm is new Nm_G (Rows => 3); 
   use Nm; 
   P : R_Matrix := ((42.0, 42.0), (43.0, 43.0), (44.0, 44.0)); 
   V : R_Vector := P (P'Last); 
begin 
   Put_Line ("v: " & V (V'First)'Img & ", " & V (V'Last)'Img); 
end Nm_Test; 

It works.

My new Nm_Test is

with Ada.Text_Io; use Ada.Text_Io; 
with Nm_G; 
procedure Nm_Test is 
   package Nm is new Nm_G (Rows => 3); 
   use Nm; 
   P : R_Matrix := ((42.0, 42.0), (43.0, 43.0), (44.0, 44.0)); 
   V,X  : R_Vector := P (P'Last);
   MLF : Long_Float := 6.0; 
begin 
   Put_Line ("v: " & V (V'First)'Img & ", " & V (V'Last)'Img); 
   X := V / MLF;
   Put_Line ("X: " & X (X'First)'Img & ", " & X(X'Last)'Img); 
end Nm_Test; 

It should also work according to the description in the ARM 2012.
However, it says: expected type "Standard.Long_Float"

Maybe it lacks implementation ?

Re: Ada.Numerics.Long_Real_Arrays

[Simon Wright]

hnptz@yahoo.de writes:

> with Ada.Text_Io; use Ada.Text_Io; 
> with Nm_G; 
> procedure Nm_Test is 
>    package Nm is new Nm_G (Rows => 3); 
>    use Nm; 
>    P : R_Matrix := ((42.0, 42.0), (43.0, 43.0), (44.0, 44.0)); 
>    V,X  : R_Vector := P (P'Last);
>    MLF : Long_Float := 6.0; 
> begin 
>    Put_Line ("v: " & V (V'First)'Img & ", " & V (V'Last)'Img); 
>    X := V / MLF;
>    Put_Line ("X: " & X (X'First)'Img & ", " & X(X'Last)'Img); 
> end Nm_Test; 
>
> It should also work according to the description in the ARM 2012.
> However, it says: expected type "Standard.Long_Float"

This is because I declared Nm_G.R_Vector as a subtype; the required
operation "/" of Ada.Numerics.Long_Real_Arrays.Real_Vector isn't
visible.

You could modify your Nm_Test to

   use type Ada.Numerics.Long_Real_Arrays.Real_Vector;

but the best approach (I think): declare Nm_G.R_Vector as a type,

   type R_Vector
   is new Ada.Numerics.Long_Real_Arrays.Real_Vector (1 .. Np);