Re: Length of unbounded_string.

[Jeffrey Carter <spam.jrcarter.not@spam.not.acm.org>]

On 11/01/2011 03:05 AM, ldries46 wrote:
> I finally have rewritten my routine continuation to try to make a work around .
> I believe that this has been succesfull.
> But The discrepancy between the display and the print facility with debugging
> stays as can be seen in the attachment. Also a strance behavior with the display
> of the character comma can be seen with lastch, that with an 'e' would have the
> output 109 'e' but for the comma gives 44 '
> I think I found a bug in the compiler so I will report this to AdaCore.

I don't see any evidence that this is a compiler error. It appears to be a 
debugger error.

17            nextlen := Length(Next_Line)	-- Next_Line is Global
18            ok1 := nextlen /= 0;

You seem to be missing a semicolon on line 17. Ok1 is never referenced.

You have two big if statements that are essentially

    if Condition then
       Do_This;
    else
       exit; -- Ok := True;
    end if;

which I would write

    exit when not Condition;

    Do_This;

The latter is clearer, especially given that small else parts tend to be 
overlooked after a large if part.

30                     while (nextch = ' ' or nextch = ASCII.HT) loop
31                        Replace_Slice(Next_Line, 1, 1, "");
32                        nextch := Element(Next_Line, 1);
33                     end loop;

Why do you use Replace_Slice with a null replacement rather than Delete?

If this loop reduces Next_Line to the null string, you'll get Constraint_Error 
from Element.

35                  str := To_Unbounded_String(Slice(str, 1, lenstr - 1));

Why do you use To_Unbounded_String (Slice (...) ) rather than Unbounded_Slice?

Cleaning this up, and removing everything not related to the processing, I came 
up with

procedure Continuation(Str : in out Unbounded_String; Nr : in out Integer) is
    Lenstr  : Integer;
    Nextlen : Integer;
    Lastch  : Character;
    Nextch  : Character;
begin
    All_Continuations : loop
       Lenstr := Length(Str);

       exit All_Continuations when Lenstr = 0;

       Lastch := Element(Str, Lenstr);
       Nextlen := Length(Next_Line);	-- Next_Line is Global

       exit All_Continuations when Lastch = ';' or Lastch = '{' or Lastch = '}' 
or Nextlen = 0;

       Nr := Nr + 1;

       Skip_Blanks : loop
       	Nextch := Element (Next_Line, 1);

         exit Skip_Blanks when Nextch /= ' ' and Nextch /= ASCII.HT;

         Delete (Source => Next_Line, From => 1, Through => 1);

         exit Skip_Blanks when Length (Next_Line) = 0;
       end loop Skip_Blanks;

       Str := Str & ' ' & Next_Line;
       -- I don't see any reason to slice the last character off and then
       -- concatenate it back on again.

       if Nr < Buffer1.Length - 1 then
          Next_Line := Buffer1.Get_Buffer( Nr + 1 );	-- Buffer1 is a global
       else
          Next_Line := Null_Unbounded_String;
       end if;
    end loop All_Continuations;
end Continuation;

-- 
Jeff Carter
"Sir Lancelot saves Sir Gallahad from almost certain temptation."
Monty Python & the Holy Grail
69