* Re: DLL creating, help ...
2002-11-01 10:21 DLL creating, help Artiom Ivanov
@ 2002-11-01 12:00 ` Jeffrey Creem
0 siblings, 0 replies; 2+ messages in thread
From: Jeffrey Creem @ 2002-11-01 12:00 UTC (permalink / raw)
If you are using GCC/GNAT 3.14 the GNAT Users Guide contains pretty complete
information. Not sure if the users guide shows up in the gcc 3.X version of
gcc yet. if not
download from ftp://ftp.cs.nyu.edu/pub/gnat the gnat 3.14 for windows and
look in there.
here is a small snapshot.
Microsoft Windows Topics
This chapter describes topics that are specific to the Microsoft Windows
platforms (NT, 95 and 98).
a.. Using GNAT on Windows
b.. CONSOLE and WINDOWS subsystems
c.. Mixed-Language Programming on Windows
d.. Windows Calling Conventions
e.. Introduction to Dynamic Link Libraries (DLLs)
f.. Using DLLs with GNAT
g.. Building DLLs with GNAT
h.. GNAT and Windows Resources
i.. Debugging a DLL
j.. GNAT and COM/DCOM Objects
Using GNAT on Windows
One of the strengths of the GNAT technology is that its tool set (gcc,
gnatbind, gnatlink, gnatmake, the gdb debugger, etc.) is used in the same
way regardless of the platform.
On Windows this tool set is complemented by a number of Microsoft-specific
tools that have been provided to facilitate interoperability with Windows
when this is required. With these tools:
a.. You can build applications using the CONSOLE or WINDOWS subsystems.
b.. You can use any Dynamically Linked Library (DLL) in your Ada code
(both relocatable and non-relocatable DLLs are supported).
c.. You can build Ada DLLs for use in other applications. These
applications can be written in a language other than Ada (e.g., C, C++,
etc). Again both relocatable and non-relocatable Ada DLLs are supported.
d.. You can include Windows resources in your Ada application.
e.. You can use or create COM/DCOM objects.
CONSOLE and WINDOWS subsystems
Under Windows there is two main subsystems. The CONSOLE subsystem (which is
the default subsystem) will always create a console when launching the
application. This is not something desirable when the application has a
Windows GUI. To get rid of this console the application must be using the
WINDOWS subsystem. To do so the -mwindows linker option must be specified.
$ gnatmake winprog -largs -mwindows
Mixed-Language Programming on Windows
Developing pure Ada applications on Windows is no different than on other
GNAT-supported platforms. However, when developing or porting an application
that contains a mix of Ada and C/C++, the choice of your Windows C/C++
development environment conditions your overall interoperability strategy.
If you use gcc to compile the non-Ada part of your application, there are no
Windows-specific restrictions that affect the overall interoperability with
your Ada code. If you plan to use Microsoft tools (e.g. Microsoft Visual
C/C++), you should be aware of the following limitations:
a.. You cannot link your Ada code with an object or library generated with
Microsoft tools if these use the .tls section (Thread Local Storage section)
since the GNAT linker does not yet support this section.
b.. You cannot link your Ada code with an object or library generated with
Microsoft tools if these use I/O routines other than those provided in the
Microsoft DLL: msvcrt.dll. This is because the GNAT run time uses the
services of msvcrt.dll for its I/Os. Use of other I/O libraries can cause a
conflict with msvcrt.dll services. For instance Visual C++ I/O stream
routines conflict with those in msvcrt.dll.
If you do want to use the Microsoft tools for your non-Ada code and hit one
of the above limitations, you have two choices:
1.. Encapsulate your non Ada code in a DLL to be linked with your Ada
application. In this case, use the Microsoft or whatever environment to
build the DLL and use GNAT to build your executable (see section Using DLLs
with GNAT).
2.. Or you can encapsulate your Ada code in a DLL to be linked with the
other part of your application. In this case, use GNAT to build the DLL (see
section Building DLLs with GNAT) and use the Microsoft or whatever
environment to build your executable.
Windows Calling Conventions
a.. C Calling Convention
b.. Stdcall Calling Convention
c.. DLL Calling Convention
When a subprogram F (caller) calls a subprogram G (callee), there are
several ways to push G's parameters on the stack and there are several
possible scenarios to clean up the stack upon G's return. A calling
convention is an agreed upon software protocol whereby the responsabilities
between the caller (F) and the callee (G) are clearly defined. Several
calling conventions are available for Windows:
a.. C (Microsoft defined)
b.. Stdcall (Microsoft defined)
c.. DLL (GNAT specific)
C Calling Convention
This is the default calling convention used when interfacing to C/C++
routines compiled with either gcc or Microsoft Visual C++.
In the C calling convention subprogram parameters are pushed on the stack by
the caller from right to left. The caller itself is in charge of cleaning up
the stack after the call. In addition, the name of a routine with C calling
convention is mangled by adding a leading underscore.
The name to use on the Ada side when importing (or exporting) a routine with
C calling convention is the name of the routine. For instance the C
function:
int get_val (long);
should be imported from Ada as follows:
function Get_Val (V : Interfaces.C.long) return Interfaces.C.int;
pragma Import (C, Get_Val, External_Name => "get_val");
Note that in this particular case the External_Name parameter could have
been omitted since, when missing, this parameter is taken to be the name of
the Ada entity in lower case. When the Link_Name parameter is missing, as in
the above example, this parameter is set to be the External_Name with a
leading underscore.
When importing a variable defined in C, you should always use the C calling
convention unless the object containing the variable is part of a DLL (in
which case you should use the DLL calling convention, see section DLL
Calling Convention).
Stdcall Calling Convention
This convention, which was the calling convention used for Pascal programs,
is used by Microsoft for all the routines in the Win32 API for efficiency
reasons. It must be used to import any routine for which this convention was
specified.
In the Stdcall calling convention subprogram parameters are pushed on the
stack by the caller from right to left. The callee (and not the caller) is
in charge of cleaning the stack on routine exit. In addition, the name of a
routine with Stdcall calling convention is mangled by adding a leading
underscore (as for the C calling convention) and a trailing @nn, where nn is
the overall size (in bytes) of the parameters passed to the routine.
The name to use on the Ada side when importing a C routine with a Stdcall
calling convention is the name of the C routine. The leading underscore and
trailing @nn are added automatically by the compiler. For instance the Win32
function:
APIENTRY int get_val (long);
should be imported from Ada as follows:
function Get_Val (V : Interfaces.C.long) return Interfaces.C.int;
pragma Import (Stdcall, Get_Val);
-- On the x86 a long is 4 bytes, so the Link_Name is "_get_val@4"
As for the C calling convention, when the External_Name parameter is
missing, it is taken to be the name of the Ada entity in lower case. If
instead of writing the above import pragma you write:
function Get_Val (V : Interfaces.C.long) return Interfaces.C.int;
pragma Import (Stdcall, Get_Val, External_Name => "retrieve_val");
then the imported routine is _retrieve_val@4. However, if instead of
specifying the External_Name parameter you specify the Link_Name as in the
following example:
function Get_Val (V : Interfaces.C.long) return Interfaces.C.int;
pragma Import (Stdcall, Get_Val, Link_Name => "retrieve_val");
then the imported routine is retrieve_val@4, that is, there is no trailing
underscore but the appropriate @nn is always added at the end of the
Link_Name by the compiler.
DLL Calling Convention
This convention, which is GNAT-specific, must be used when you want to
import in Ada a variables defined in a DLL. For functions and procedures
this convention is equivalent to the Stdcall convention. As an example, if a
DLL contains a variable defined as:
int my_var;
then, to access this variable from Ada you should write:
My_Var : Interfaces.C.int;
pragma Import (DLL, My_Var);
The remarks concerning the External_Name and Link_Name parameters given in
the previous sections equally apply to the DLL calling convention.
Introduction to Dynamic Link Libraries (DLLs)
A Dynamically Linked Library (DLL) is a library that can be shared by
several applications running under Windows. A DLL can contain any number of
routines and variables.
One advantage of DLLs is that you can change and enhance them without
forcing all the applications that depend on them to be relinked or
recompiled. However, you should be aware than all calls to DLL routines are
slower since, as you will understand below, such calls are indirect.
To illustrate the remainder of this section, suppose that an application
wants to use the services of a DLL `API.dll'. To use the services provided
by `API.dll' you must statically link against an import library which
contains a jump table with an entry for each routine and variable exported
by the DLL. In the Microsoft world this import library is called `API.lib'.
When using GNAT this import library is called either `libAPI.a' or
`libapi.a' (names are case insensitive).
After you have statically linked your application with the import library
and you run your application, here is what happens:
1.. Your application is loaded into memory.
2.. The DLL `API.dll' is mapped into the address space of your
application. This means that:
a.. The DLL will use the stack of the calling thread.
b.. The DLL will use the virtual address space of the calling process.
c.. The DLL will allocate memory from the virtual address space of the
calling process.
d.. Handles (pointers) can be safely exchanged between routines in the
DLL routines and routines in the application using the DLL.
3.. The entries in the `libAPI.a' or `API.lib' jump table which is part of
your application are initialized with the addresses of the routines and
variables in `API.dll'.
4.. If present in `API.dll', routines DllMain or DllMainCRTStartup are
invoked. These routines typically contain the initialization code needed for
the well-being of the routines and variables exported by the DLL.
There is an additional point which is worth mentioning. In the Windows world
there are two kind of DLLs: relocatable and non-relocatable DLLs.
Non-relocatable DLLs can only be loaded at a very specific address in the
target application address space. If the addresses of two non-relocatable
DLLs overlap and these happen to be used by the same application, a conflict
will occur and the application will run incorrectly. Hence, when possible,
it is always preferable to use and build relocatable DLLs. Both relocatable
and non-relocatable DLLs are supported by GNAT.
As a side note, an interesting difference between Microsoft DLLs and Unix
shared libraries, is the fact that on most Unix systems all public routines
are exported by default in a Unix shared library, while under Windows the
exported routines must be listed explicitly in a definition file (see
section The Definition File).
Using DLLs with GNAT
a.. Creating an Ada Spec for the DLL Services
b.. Creating an Import Library
To use the services of a DLL, say `API.dll', in your Ada application you
must have:
1.. The Ada spec for the routines and/or variables you want to access in
`API.dll'. If not available this Ada spec must be built from the C/C++
header files provided with the DLL.
2.. The import library (`libAPI.a' or `API.lib'). As previously mentioned
an import library is a statically linked library containing the import table
which will be filled at load time to point to the actual `API.dll' routines.
Sometimes you don't have an import library for the DLL you want to use. The
following sections will explain how to build one.
3.. The actual DLL, `API.dll'.
Once you have all the above, to compile an Ada application that uses the
services of `API.dll' and whose main subprogram is My_Ada_App, you simply
issue the command
$ gnatmake my_ada_app -largs -lAPI
The argument -largs -lAPI at the end of the gnatmake command tells the GNAT
linker to look first for a library named `API.lib' (Microsoft-style name)
and if not found for a library named `libAPI.a' (GNAT-style name). Note that
if the Ada package spec for `API.dll' contains the following pragma
pragma Linker_Options ("-lAPI");
you do not have to add -largs -lAPI at the end of the gnatmake command.
If any one of the items above is missing you will have to create it
yourself. The following sections explain how to do so using as an example a
fictitious DLL called `API.dll'.
Creating an Ada Spec for the DLL Services
A DLL typically comes with a C/C++ header file which provides the
definitions of the routines and variables exported by the DLL. The Ada
equivalent of this header file is a package spec that contains definitions
for the imported entities. If the DLL you intend to use does not come with
an Ada spec you have to generate one such spec yourself. For example if the
header file of `API.dll' is a file `api.h' containing the following two
definitions:
int some_var;
int get (char *);
then the equivalent Ada spec could be:
with Interfaces.C.Strings;
package API is
use Interfaces;
Some_Var : C.int;
function Get (Str : C.Strings.Chars_Ptr) return C.int;
private
pragma Import (C, Get);
pragma Import (DLL, Some_Var);
end API;
Note that a variable is always imported with a DLL convention. A function
can have C, Stdcall or DLL convention. For subprograms, the DLL convention
is a synonym of Stdcall (see section Windows Calling Conventions).
Creating an Import Library
a.. The Definition File
b.. GNAT-Style Import Library
c.. Microsoft-Style Import Library
If a Microsoft-style import library `API.lib' or a GNAT-style import library
`libAPI.a' is available with `API.dll' you can skip this section. Otherwise
read on.
The Definition File
As previously mentioned, and unlike Unix systems, the list of symbols that
are exported from a DLL must be provided explicitly in Windows. The main
goal of a definition file is precisely that: list the symbols exported by a
DLL. A definition file (usually a file with a .def suffix) has the following
structure:
[LIBRARY name]
[DESCRIPTION string]
EXPORTS
symbol1
symbol2
...
LIBRARY name
This section, which is optional, gives the name of the DLL.
DESCRIPTION string
This section, which is optional, gives a description string that will be
embedded in the import library.
EXPORTS
This section gives the list of exported symbols (procedures, functions or
variables). For instance in the case of `API.dll' the EXPORTS section of
`API.def' looks like:
EXPORTS
some_var
get
Note that you must specify the correct suffix (@nn) (see section Windows
Calling Conventions) for a Stdcall calling convention function in the
exported symbols list.
There can actually be other sections in a definition file, but these
sections are not relevant to the discussion at hand.
GNAT-Style Import Library
To create a static import library from `API.dll' with the GNAT tools you
should proceed as follows:
1.. Create the definition file `API.def' (see section The Definition
File). For that use the dll2def tool as follows:
$ dll2def API.dll > API.def
dll2def is a very simple tool: it takes as input a DLL and prints to
standard output the list of entry points in the DLL. Note that if some
routines in the DLL have the Stdcall convention (see section Windows Calling
Conventions) then you'll have to edit `api.def' to add the needed @nn
suffix.
2.. Build the import library libAPI.a, using gnatdll (see section Using
gnatdll) as follows:
$ gnatdll -e API.def -d API.dll
gnatdll takes as input a definition file `API.def' and the name of the DLL
containing the services listed in the definition file `API.dll'. The name of
the static import library generated is computed from the name of the
definition file as follows: if the definition file name is xyz.def, the
import library name will be libxyz.a. Note that in the previous example
option -e could have been removed because the name of the definition file
(before the ".def" suffix) is the same as the name of the DLL (see section
Using gnatdll for more information about gnatdll).
Microsoft-Style Import Library
With GNAT you can either use a GNAT-style or Microsoft-style import library.
A Microsoft import library is needed only if you plan to make an Ada DLL
available to applications developed with Microsoft tools (see section
Mixed-Language Programming on Windows).
To create a Microsoft-style import library for `API.dll' you should proceed
as follows:
1.. Create the definition file `API.def' from the DLL. For this use either
the dll2def tool as described above or the Microsoft dumpbin tool (see the
corresponding Microsoft documentation for further details).
2.. Build the actual import library using Microsoft's lib utility:
$ lib -machine:IX86 -def:API.def -out:API.lib
If you use the above command the definition file `API.def' must contain a
line giving the name of the DLL:
LIBRARY "API"
See the Microsoft documentation for further details about the usage of lib.
Building DLLs with GNAT
a.. Limitations When Using Ada DLLs from Ada
b.. Exporting Ada Entities
c.. Ada DLLs and Elaboration
d.. Ada DLLs and Finalization
e.. Creating a Spec for Ada DLLs
f.. Creating the Definition File
g.. Using gnatdll
This section explains how to build DLLs containing Ada code. These DLLs will
be referred to as Ada DLLs in the remainder of this section.
The steps required to build an Ada DLL that is to be used by Ada as well as
non-Ada applications are as follows:
1.. You need to mark each Ada entity exported by the DLL with a C or
Stdcall calling convention to avoid any Ada name mangling for the entities
exported by the DLL (see section Exporting Ada Entities). You can skip this
step if you plan to use the Ada DLL only from Ada applications.
2.. Your Ada code must export an initialization routine which calls the
routine adainit generated by gnatbind to perform the elaboration of the Ada
code in the DLL (see section Ada DLLs and Elaboration). The initialization
routine exported by the Ada DLL must be invoked by the clients of the DLL to
initialize the DLL.
3.. When useful, the DLL should also export a finalization routine which
calls routine adafinal generated by gnatbind to perform the finalization of
the Ada code in the DLL (see section Ada DLLs and Finalization). The
finalization routine exported by the Ada DLL must be invoked by the clients
of the DLL when the DLL services are no further needed.
4.. You must provide a spec for the services exported by the Ada DLL in
each of the programming languages to which you plan to make the DLL
available.
5.. You must provide a definition file listing the exported entities (see
section The Definition File).
6.. Finally you must use gnatdll to produce the DLL and the import library
(see section Using gnatdll).
Limitations When Using Ada DLLs from Ada
When using Ada DLLs from Ada applications there is a limitation users should
be aware of. Because on Windows the GNAT run time is not in a DLL of its
own, each Ada DLL includes a part of the GNAT run time. Specifically, each
Ada DLL includes the services of the GNAT run time that are necessary to the
Ada code inside the DLL. As a result, when an Ada program uses an Ada DLL
there are two independent GNAT run times: one in the Ada DLL and one in the
main program.
It is therefore not possible to exchange GNAT run-time objects between the
Ada DLL and the main Ada program. Example of GNAT run-time objects are file
handles (e.g. Text_IO.File_Type), tasks types, protected objects types, etc.
It is completely safe to exchange plain elementary, array or record types,
Windows object handles, etc.
Exporting Ada Entities
Building a DLL is a way to encapsulate a set of services usable from any
application. As a result, the Ada entities exported by a DLL should be
exported with the C or Stdcall calling conventions to avoid any Ada name
mangling. Please note that the Stdcall convention should only be used for
subprograms, not for variables. As an example here is an Ada package API,
spec and body, exporting two procedures, a function, and a variable:
with Interfaces.C; use Interfaces;
package API is
Count : C.int := 0;
function Factorial (Val : C.int) return C.int;
procedure Initialize_API;
procedure Finalize_API;
-- Initialization & Finalization routines. More in the next section.
private
pragma Export (C, Initialize_API);
pragma Export (C, Finalize_API);
pragma Export (C, Count);
pragma Export (C, Factorial);
end API;
package body API is
function Factorial (Val : C.int) return C.int is
Fact : C.int := 1;
begin
Count := Count + 1;
for K in 1 .. Val loop
Fact := Fact * K;
end loop;
return Fact;
end Factorial;
procedure Initialize_API is
procedure Adainit;
pragma Import (C, Adainit);
begin
Adainit;
end Initialize_API;
procedure Finalize_API is
procedure Adafinal;
pragma Import (C, Adafinal);
begin
Adafinal;
end Finalize_API;
end API;
If the Ada DLL you are building will only be used by Ada applications you do
not have to export Ada entities with a C or Stdcall convention. As an
example, the previous package could be written as follows:
package API is
Count : Integer := 0;
function Factorial (Val : Integer) return Integer;
procedure Initialize_API;
procedure Finalize_API;
-- Initialization and Finalization routines.
end API;
package body API is
function Factorial (Val : Integer) return Integer is
Fact : Integer := 1;
begin
Count := Count + 1;
for K in 1 .. Val loop
Fact := Fact * K;
end loop;
return Fact;
end Factorial;
...
-- The remainder of this package body is unchanged.
end API;
Note that if you do not export the Ada entities with a C or Stdcall
convention you will have to provide the mangled Ada names in the definition
file of the Ada DLL (see section Creating the Definition File).
Ada DLLs and Elaboration
The DLL that you are building contains your Ada code as well as all the
routines in the Ada library that are needed by it. The first thing a user of
your DLL must do is elaborate the Ada code (see section Elaboration Order
Handling in GNAT).
To achieve this you must export an initialization routine (Initialize_API in
the previous example), which must be invoked before using any of the DLL
services. This elaboration routine must call the Ada elaboration routine
adainit generated by the GNAT binder (see section Binding with Non-Ada Main
Programs). See the body of Initialize_Api for an example. Note that the GNAT
binder is automatically invoked during the DLL build process by the gnatdll
tool (see section Using gnatdll).
When a DLL is loaded, Windows systematically invokes a routine called
DllMain. It would therefore be possible to call adainit directly from
DllMain without having to provide an explicit initialization routine.
Unfortunately, it is not possible to call adainit from the DllMain if your
program has library level tasks because access to the DllMain entry point is
serialized by the system (that is, only a single thread can execute
"through" it at a time), which means that the GNAT run time will deadlock
waiting for the newly created task to complete its initialization.
Ada DLLs and Finalization
When the services of an Ada DLL are no longer needed, the client code should
invoke the DLL finalization routine, if available. The DLL finalization
routine is in charge of releasing all resources acquired by the DLL. In the
case of the Ada code contained in the DLL, this is achieved by calling
routine adafinal generated by the GNAT binder (see section Binding with
Non-Ada Main Programs). See the body of Finalize_Api for an example. As
already pointed out the GNAT binder is automatically invoked during the DLL
build process by the gnatdll tool (see section Using gnatdll).
Creating a Spec for Ada DLLs
To use the services exported by the Ada DLL from another programming
language (e.g. C), you have to translate the specs of the exported Ada
entities in that language. For instance in the case of API.dll, the
corresponding C header file could look like:
extern int *__imp__count;
#define count (*__imp__count)
int factorial (int);
It is important to understand that when building an Ada DLL to be used by
other Ada applications, you need two different specs for the packages
contained in the DLL: one for building the DLL and the other for using the
DLL. This is because the DLL calling convention is needed to use a variable
defined in a DLL, but when building the DLL, the variable must have either
the Ada or C calling convention. As an example consider a DLL comprising the
following package API:
package API is
Count : Integer := 0;
...
-- Remainder of the package omitted.
end API;
After producing a DLL containing package API, the spec that must be used to
import API.Count from Ada code outside of the DLL is:
package API is
Count : Integer;
pragma Import (DLL, Count);
end API;
Creating the Definition File
The definition file is the last file needed to build the DLL. It lists the
exported symbols. As an example, the definition file for a DLL containing
only package API (where all the entities are exported with a C calling
convention) is:
EXPORTS
count
factorial
finalize_api
initialize_api
If the C calling convention is missing from package API, then the definition
file contains the mangled Ada names of the above entities, which in this
case are:
EXPORTS
api__count
api__factorial
api__finalize_api
api__initialize_api
Using gnatdll
a.. gnatdll Example
b.. gnatdll behind the Scenes
c.. Using dlltool
gnatdll is a tool to automate the DLL build process once all the Ada and
non-Ada sources that make up your DLL have been compiled. gnatdll is
actually in charge of two distinct tasks: build the static import library
for the DLL and the actual DLL. The form of the gnatdll command is
$ gnatdll [switches] list-of-files [-largs opts]
where list-of-files is a list of ALI and object files. The object file list
must be the exact list of objects corresponding to the non-Ada sources whose
services are to be included in the DLL. The ALI file list must be the exact
list of ALI files for the corresponding Ada sources whose services are to be
included in the DLL. If list-of-files is missing, only the static import
library is generated.
You may specify any of the following switches to gnatdll:
-a[address]
Build a non-relocatable DLL at address. If address is not specified the
default address 0x11000000 will be used. By default, when this switch is
missing, gnatdll builds relocatable DLL. We advise the reader to build
relocatable DLL.
-d dllfile
dllfile is the name of the DLL. This switch must be present for gnatdll to
do anything. The name of the generated import library is obtained
algorithmically from dllfile as shown in the following example: if dllfile
is xyz.dll, the import library name is libxyz.a. The name of the definition
file to use (if not specified by option -e) is obtained algorithmically from
dllfile as shown in the following example: if dllfile is xyz.dll, the
definition file used is xyz.def.
-e deffile
deffile is the name of the definition file.
-h
Help mode. Displays gnatdll switch usage information.
-Idir
Direct gnatdll to search the dir directory for source and object files
needed to build the DLL. (see section Search Paths and the Run-Time Library
(RTL)).
-k
Removes the @nn suffix from the import library's exported names. You must
specified this option if you want to use a Stdcall function in a DLL for
which the @nn suffix has been removed. This is the case for most of the
Windows NT DLL for example. This option has no effect when -n option is
specified.
-l file
The list of ALI and object files used to build the DLL are listed in file,
instead of being given in the command line. Each line in file contains the
name of an ALI or object file.
-n
No Import. Do not create the import library.
-q
Quiet mode. Do not display unnecessary messages.
-v
Verbose mode. Display extra information.
-largs opts
Linker options. Pass opts to the linker.
gnatdll Example
As an example the command to build a relocatable DLL from `api.adb' once
`api.adb' has been compiled and `api.def' created is
$ gnatdll -d api.dll api.ali
The above command creates two files: `libapi.a' (the import library) and
`api.dll' (the actual DLL). If you want to create only the DLL, just type:
$ gnatdll -d api.dll -n api.ali
Alternatively if you want to create just the import library, type:
$ gnatdll -d api.dll
gnatdll behind the Scenes
This section details the steps involved in creating a DLL. gnatdll does
these steps for you. Unless you are interested in understanding what goes on
behind the scenes, you should skip this section.
We use the previous example of a DLL containing the Ada package API, to
illustrate the steps necessary to build a DLL. The starting point is a set
of objects that will make up the DLL and the corresponding ALI files. In the
case of this example this means that `api.o' and `api.ali' are available. To
build a relocatable DLL, gnatdll does the following:
1.. gnatdll builds the base file (`api.base'). A base file gives the
information necessary to generate relocation information for the DLL.
$ gnatbind -n api
$ gnatlink api -o api.jnk -mdll -Wl,--base-file,api.base
In addition to the base file, the gnatlink command generates an output file
`api.jnk' which can be discarded. The -mdll switch asks gnatlink to generate
the routines DllMain and DllMainCRTStartup that are called by the Windows
loader when the DLL is loaded into memory.
2.. gnatdll uses dlltool (see section Using dlltool) to build the export
table (`api.exp'). The export table contains the relocation information in a
form which can be used during the final link to ensure that the Windows
loader is able to place the DLL anywhere in memory.
$ dlltool --dllname api.dll --def api.def --base-file api.base \
--output-exp api.exp
3.. gnatdll builds the base file using the new export table. Note that
gnatbind must be called once again since the binder generated file has been
deleted during the previous call to gnatlink.
$ gnatbind -n api
$ gnatlink api -o api.jnk api.exp -mdll
-Wl,--base-file,api.base
4.. gnatdll builds the new export table using the new base file and
generates the DLL import library `libAPI.a'.
$ dlltool --dllname api.dll --def api.def --base-file api.base \
--output-exp api.exp --output-lib libAPI.a
5.. Finally gnatdll builds the relocatable DLL using the final export table.
$ gnatbind -n api
$ gnatlink api api.exp -o api.dll -mdll
Using dlltool
dlltool is the low-level tool used by gnatdll to build DLLs and static
import libraries. This section summarizes the most common dlltool switches.
The form of the dlltool command is
$ dlltool [switches]
dlltool switches include:
--base-file basefile
Read the base file basefile generated by the linker. This switch is used
to create a relocatable DLL.
--def deffile
Read the definition file.
--dllname name
Gives the name of the DLL. This switch is used to embed the name of the
DLL in the static import library generated by dlltool with
switch --output-lib.
-k
Kill @nn from exported names (see section Windows Calling Conventions for
a discussion about Stdcall-style symbols.
--help
Prints the dlltool switches with a concise description.
--output-exp exportfile
Generate an export file exportfile. The export file contains the export
table (list of symbols in the DLL) and is used to create the DLL.
--output-lib libfile
Generate a static import library libfile.
-v
Verbose mode.
--as assembler-name
Use assembler-name as the assembler. The default is as.
GNAT and Windows Resources
a.. Building Resources
b.. Compiling Resources
c.. Using Resources
d.. Limitations
Resources are an easy way to add Windows specific objects to your
application. The objects that can be added as resources include:
a.. menus
b.. accelerators
c.. dialog boxes
d.. string tables
e.. bitmaps
f.. cursors
g.. icons
h.. fonts
This section explains how to build, compile and use resources.
Building Resources
A resource file is an ASCII file. By convention resource files have an `.rc'
extension. The easiest way to build a resource file is to use Microsoft
tools such as imagedit.exe to build bitmaps, icons and cursors and
dlgedit.exe to build dialogs. It is always possible to build an `.rc' file
yourself by writing a resource script.
It is not our objective to explain how to write a resource file. A complete
description of the resource script language can be found in the Microsoft
documentation.
Compiling Resources
This section describes how to build a GNAT-compatible (COFF) object file
containing the resources. This is done using the Resource Compiler rcl as
follows:
$ rcl -i myres.rc -o myres.o
By default rcl will run gcc to preprocess the `.rc' file. You can specify an
alternate preprocessor (usually named `cpp.exe') using the rcl -cpp
parameter. A list of all possible options may be obtained by entering the
command rcl with no parameters.
It is also possible to use the Microsoft resource compiler rc.exe to produce
a `.res' file (binary resource file). See the corresponding Microsoft
documentation for further details. In this case you need to use res2coff to
translate the `.res' file to a GNAT-compatible object file as follows:
$ res2coff -i myres.res -o myres.o
Using Resources
To include the resource file in your program just add the GNAT-compatible
object file for the resource(s) to the linker arguments. With gnatmake this
is done by using the -largs option:
$ gnatmake myprog -largs myres.o
Limitations
In this section we describe the current limitations together with
suggestions for workarounds.
a.. rcl does not handle the RCINCLUDE directive.
Workaround: replace RCINCLUDE by an #include directive.
b.. rcl does not handle the brackets as block delimiters.
Workaround: replace character '{' by BEGIN and '}' by END. Note that
Microsoft's rc handles both forms of block delimiters.
c.. rcl does not handle TypeLib resources. This type of resource is used
to build COM, DCOM or ActiveX objects.
Workaround: use rc, the Microsoft resource compiler.
d.. It is not possible to use strip to remove the debugging symbols from a
program with resources.
Workaround: use linker option -s to strip debugging symbols from the final
executable.
Debugging a DLL
a.. The Program and the DLL Are Built with GCC/GNAT
b.. The Program Is Built with Some Foreign Tools and the DLL Is Built with
GCC/GNAT
Debugging a DLL is similar to debugging a standard program. But we have to
deal with two different executable parts: the DLL and the program that uses
it. We have the following four posibilities:
1.. The program and the DLL are built with GCC/GNAT.
2.. The program is built with foreign tools and the DLL is built with
GCC/GNAT.
3.. The program is built with GCC/GNAT and the DLL is built with foreign
tools.
4..
In this section we address only cases one and two above. There is no point
in trying to debug a DLL with GNU/GDB, if there is no GDB-compatible
debugging information in it. To do so you must use a debugger compatible
with the tools suite used to build the DLL.
The Program and the DLL Are Built with GCC/GNAT
This is the simplest case. Both the DLL and the program have GDB compatible
debugging information. It is then possible to break anywhere in the process.
Let's suppose here that the main procedure is named ada_main and that in the
DLL there is an entry point named ada_dll.
The DLL (see section Introduction to Dynamic Link Libraries (DLLs)) and
program must have been built with the debugging information (see GNAT -g
switch). Here are the step-by-step instructions for debugging it:
1.. Launch GDB on the main program.
$ gdb -nw ada_main
2.. Break on the main procedure and run the program.
(gdb) break ada_main
(gdb) run
This step is required to be able to set a breakpoint inside the DLL. As long
as the program is not run, the DLL is not loaded. This has the consequence
that the DLL debugging information is also not loaded, so it is not possible
to set a breakpoint in the DLL.
3.. Set a breakpoint inside the DLL
(gdb) break ada_dll
(gdb) run
At this stage a breakpoint is set inside the DLL. From there on you can use
the standard approach to debug the whole program (see section Running and
Debugging Ada Programs).
The Program Is Built with Some Foreign Tools and the DLL Is Built with
GCC/GNAT
a.. Debugging the DLL Directly
b.. Attaching to a Running Process
In this case things are slightly more complex because it is not possible to
start the main program and then break at the beginning to load the DLL and
the associated DLL debugging information. It is not possible to break at the
beginning of the program because there is no GDB debugging information, and
therefore there is no direct way of getting initial control. This section
addresses this issue by describing some methods that can be used to break
somewhere in the DLL to debug it.
First suppose that the main procedure is named main (this is for example
some C code built with Microsoft Visual C) and that there is a DLL named
test.dll containing an Ada entry point named ada_dll.
The DLL (see section Introduction to Dynamic Link Libraries (DLLs)) must
have been built with debugging information (see GNAT -g option).
Debugging the DLL Directly
1.. Launch the debugger on the DLL.
$ gdb -nw test.dll
2.. Set a breakpoint on a DLL subroutine.
(gdb) break ada_dll
3.. Specify the executable file to GDB.
(gdb) exec-file main.exe
4.. Run the program.
(gdb) run
This will run the program until it reaches the breakpoint that has been set.
From that point you can use the standard way to debug a program as described
in (see section Running and Debugging Ada Programs).
It is also possible to debug the DLL by attaching to a running process.
Attaching to a Running Process
With GDB it is always possible to debug a running process by attaching to
it. It is possible to debug a DLL this way. The limitation of this approach
is that the DLL must run long enough to perform the attach operation. It may
be useful for instance to insert a time wasting loop in the code of the DLL
to meet this criterion.
1.. Launch the main program `main.exe'.
$ main
2.. Use the Windows Task Manager to find the process ID. Let's say that the
process PID for `main.exe' is 208.
3.. Launch gdb.
$ gdb -nw
4.. Attach to the running process to be debugged.
(gdb) attach 208
5.. Load the process debugging information.
(gdb) symbol-file main.exe
6.. Break somewhere in the DLL.
(gdb) break ada_dll
7.. Continue process execution.
(gdb) continue
This last step will resume the process execution, and stop at the breakpoint
we have set. From there you can use the standard approach to debug a program
as described in (see section Running and Debugging Ada Programs).
GNAT and COM/DCOM Objects
This section is temporarily left blank.
Performance Considerations
The GNAT system provides a number of options that allow a trade-off between
a.. performance of the generated code
b.. speed of compilation
c.. minimization of dependences and recompilation
d.. the degree of run-time checking.
The defaults (if no options are selected) aim at improving the speed of
compilation and minimizing dependences, at the expense of performance of the
generated code:
a.. no optimization
b.. no inlining of subprogram calls
c.. all run-time checks enabled except overflow and elaboration checks
These options are suitable for most program development purposes. This
chapter describes how you can modify these choices, and also provides some
guidelines on debugging optimized code.
a.. Controlling Run-Time Checks
b.. Optimization Levels
c.. Debugging Optimized Code
d.. Inlining of Subprograms
Controlling Run-Time Checks
By default, GNAT produces all run-time checks, except arithmetic overflow
checking for integer operations (that includes division by zero) and checks
for access before elaboration on subprogram calls. Two gnat switches, -gnatp
and -gnato allow this default to be modified. See section Run-Time Checks.
Our experience is that the default is suitable for most development
purposes.
We treat integer overflow specially because these are quite expensive and in
our experience are not as important as other run-time checks in the
development process.
Elaboration checks are off by default, and also not needed by default, since
GNAT uses a static elaboration analysis approach that avoids the need for
run-time checking. This manual contains a full chapter discussing the issue
of elaboration checks, and if the default is not satisfactory for your use,
you should read this chapter.
Note that the setting of the switches controls the default setting of the
checks. They may be modified using either pragma Suppress (to remove checks)
or pragma Unsuppress (to add back suppressed checks) in the program source.
"Artiom Ivanov" <rarelang@ua.fm> wrote in message
news:aptkkl$6dl$1@news.lucky.net...
> Please some one help me to resolve this problem:
> I want to create a DLL and to export a function.
> My problem is that i can't understand how to proceed with gcc to do such
> topic
> (to create a DLL using gcc, and to export a function written in ADA95
> language)
> Please send me some example ready to be compiled and some instructions,
> please.
> Thanks in advance.
>
> An additional question:
> How to export a class method into DLL (using gcc)?
>
>
^ permalink raw reply [flat|nested] 2+ messages in thread