Re: Freezing a task

[Anh Vo <anhvofrcaus@gmail.com>]

On Nov 17, 11:24 pm, a...@att.net wrote:
> --
> --  Complete Program
> --
>
> with Text_IO ;
>
> procedure u is
>
>   use Text_IO ;
>
>   task type test is
>       entry Start ;    -- initialize and start task
>                        -- and task can die if parent stops
>
>       entry Wait ;     -- Send task to sleep for a while
>                        -- and task can die if parent stops
>
>       entry Continue ; -- wake up task
>       entry Stop ;     -- stops and kill task
>   end test ;
>
>   task body test is
>
>       Count : Integer ;
>     begin
>       --  Initialize task
>       Count := 0  ;
>       Outer_Loop : loop
>         select
>           --  start task
>           accept Start ;
>             Put_Line ( "Start" ) ;
>
>             Main_Loop : loop
>               select
>
>                 --  pause task
>                 accept Wait ;
>                   Put_Line ( "Wait" ) ;
>                   New_Line ;
>
>                   select
>
>                     --  sofware wake up task
>                     accept Continue ;
>                       Put_Line ( "Continue" ) ;
>
>                   --  software exit while in wait mode
>                   or
>                     accept Stop ;
>                       Put_Line ( "Stop" ) ;
>                       exit Outer_Loop ;
>
>                   --  exit if parent fails while in wait mode
>                   or
>                     terminate ;
>                   end select ;
>
>               --  software exit (abort) while in normal
>               --  execution mode
>               or
>                 accept Stop ;
>                     Put_Line ( "Stop" ) ;
>                     exit Outer_Loop ;
>
>               else
>                 -- - - - - - - - - - - --
>                 --  Main Tasking Code  --
>                 -- - - - - - - - - - - --
>                 Put ( "Testing" ) ;
>                 Put ( Integer'Image ( Count ) ) ;
>                 New_Line ;
>                 Count := Count + 1 ;
>               end select ;
>           end loop Main_Loop ;
>
>         --  exit if parent fails
>         or
>           terminate ;
>         end select ;
>       end loop Outer_Loop ;
>       Put_Line ( "Task has Terminated" ) ;
>     end test ;
>
>  testing_task      : test ;
>
> begin
>   Put_Line ( "Start Tasking" ) ;
>   New_Line ;
>   --
>   testing_task.Start ;
>   delay ( 0.01 ) ;
>   testing_task.Wait ;
>   delay ( 1.0 ) ;
>   testing_task.Continue ;
>   delay ( 0.01 ) ;
>   testing_task.Wait ;
>   --
>   delay ( 1.0 ) ;
>   testing_task.Stop ;
>   delay ( 0.5 ) ;
>   New_Line ;
> end u ;

I am not sure what was meant by couple of annotated comments
mentioning parent fails. Normally, tasks are declared at library
level. Thus, they will terminate when the main program terminates. In
this particular example, the task will terminate when the main
procedure terminates.

Anh Vo