Full view of a private partial view cannot be a subtype

[Jere <jhb.chat@gmail.com>]

Say I have some type:

   package Base is
      type Instance is tagged limited private;
      procedure Operation(Object : in out Instance);
   private
      type Instance is tagged limited null record;
      procedure Operation(Object : in out Instance) is null;
   end Base;

It might have 20 or so operations, but this is a simplified
example.  There are times where in another package I want to
subtype Base.Instance and do renames of the operations in order
to bring them all into scope (or whatever the correct term is):

   package New_Type1 is
      subtype Instance is Base.Instance;
      procedure Operation(Object : in out Instance);
      
   private
      
      procedure Operation(Object : in out Instance) renames Base.Operation;
   end New_Type1;

(NOTE:  is there a better way to do this?)

This is all well and good, but sometimes while I as an implementer
want this kind of relationship, I don't necessarily want to expose
that relationship outside the private section of a package.  Here I 
run into a problem as I cannot (as far as I can tell) do:

   package New_Type2 is
      type Instance is tagged limited private;
      procedure Operation(Object : in out Instance);
   private
      subtype Instance is Base.Instance;
      procedure Operation(Object : in out Instance renames Base.Operation;
   end New_Type2;

as it fails with an error ("Instance" not type conformant with declaration)
on the subtype line.

Instead I have to do (again, unless there is a better way):

   package New_Type2 is
      type Instance is tagged limited private;
      procedure Operation(Object : in out Instance);
      
   private
      type Instance is new Base.Instance with null record;
   end New_Type2;
   
   package body New_Type2 is
      procedure Operation(Object : in out Instance) is
      begin
         Base.Instance(Object).Operation;
      end Operation;
   end New_Type2;

This might be ok, but it's a lot of noise added (I now
need a body for all of my operations and need to type
convert parameters and any return values).  I'm also not
sure the semantics between the method I wanted and the
method I had to use are the same (in all situations).  I.E.
I don't know if 

   procedure Operation(Object : in out Instance renames Base.Operation;

has the same semantics as

   procedure Operation(Object : in out Instance) is
   begin
      Base.Instance(Object).Operation;
   end Operation;

My instinct says they do not.  That may be ok, but I am 
just unsure.  

So I guess my question is two part:

1.  Is there a way to make the full view of a private type
    a subtype when the partial view is not a subtype? Or am
    I forced to derive a new type?

2.  If it isn't possible, are there any language reasons for
    why that must be so?  Would making a full view of a type
    actually a subtype under the hood break something?