Re: abstract sub programs overriding

[Georg Bauhaus <sb463ba@l1-hrz.uni-duisburg.de>]

Hyman Rosen <hyrosen@mail.com> wrote:
: 
: But it also means that initializing a field of B cannot safely use A!

So it seems. Here is an example producing
Init field of B
hook has val -1073743060
Init B

when the main subprogram has a declaration of a variable of type
B but not of type A. When a variable of type A is added before
the B variable, the B variables initial hook val becomes 0.
If an A variable is declared after a B variable, the Natural
hook val stays at -1073743060. (GCC 3.1 Mac OS X)

with Ada.Finalization;  use Ada.Finalization;
package Foo is

   type Hook is tagged record  -- not part of hierarchy
      val: Natural;  -- should not have negative values
   end record;

   procedure hook_op(ref: access Hook);

   type A is new Controlled with record
      a_part: aliased Hook;
   end record;
   procedure Initialize(Object: in out A);

   type In_B is new Controlled with null record;
   procedure Initialize(object: in out In_B);

   type B is new A with record
      field: In_B;
   end record;
   procedure Initialize(Object: in out B);

end foo;


with Ada.Text_IO;  use Ada.Text_IO;
package body Foo is

   procedure hook_op(ref: access Hook) is
   begin
      put_line("hook has val " & Natural'image(ref.val));
   end hook_op;

   procedure Initialize (Object : in out A) is
   begin
      Put_Line ("Init A");
   end Initialize ;

   procedure Initialize (Object : in out B) is
   begin
      hook_op(Object.a_part'access);
      Put_Line ("Init B");
   end Initialize ;

   procedure Initialize (Object : in out In_B) is
   begin
      Put_Line ("Init field of B");
   end Initialize;
end Foo;