Re: Weird problem with recursion and tasks

["Dmitry A. Kazakov" <mailbox@dmitry-kazakov.de>]

On 2 Dec 2006 19:21:14 -0800, christopher.orihuela@gmail.com wrote:

> I was implementing a concurrent version of QuickSort (each half in a
> different task) when I realized that sometimes the recursive task
> didn't execute.
> �Could anybody tell me why for values of MaxI > 4 I allways get a
> higer count of A in the following program? Thanks.

It looks like a compiler bug to me (GNAT 3.15p, Windows). If we added a few
put_lines:

With Ada.Text_IO, Ada.Strings.Fixed;
Use  Ada.Text_IO, Ada.Strings.Fixed;

Procedure My_Proc is

   protected type Counter is
      Procedure IncA;
      Procedure IncB;
      Procedure ShowCounts;
   private
      A, B: Natural := 0;
   end Counter;

   protected body Counter is
      Procedure IncA is
      begin
         A := A+1;
      end IncA;
      Procedure IncB is
      begin
         B := B+1;
      end IncB;
      Procedure ShowCounts is
      begin
         Put_Line("A: " & Integer'Image(A));
         Put_Line("B: " & Integer'Image(B));
      end ShowCounts;
   end Counter;

   MyCounter : Counter;

   Procedure Recursive (I : Natural; MaxI : Natural) is
   begin

      if (I >= MaxI) then
           return;
      end if;

      MyCounter.IncA;
      MyCounter.IncA;

      declare
         task My_Recursive_Task;
         task body My_Recursive_Task is
         begin
            Put_Line(I * " " & "Start task");
            Recursive(I+1, MaxI);
            MyCounter.IncB;
            Put_Line(I * " " & "Stop task");
         end My_Recursive_Task;

      begin
         Recursive(I+1, MaxI);
         MyCounter.IncB;
      end;

   end Recursive;
   
begin
   Recursive (1, 5);
   MyCounter.ShowCounts;
end My_Proc;

we would see that starting with MaxI=4 and higher some of My_Recursive_Task
are not awaited for termination by their masters, when the task object gets
out of scope. I see it in breach with ARM 7.6.1(4).

-- 
Regards,
Dmitry A. Kazakov
http://www.dmitry-kazakov.de