Re: New limited range type?

[martin.dowie@btopenworld.com (Martin Dowie)]

> > How about:
> > 
> >    function S'Limit (X:...
> 
> Or maybe Limit_to_Bounds? Wordy, but clearer.

I still prefer 'Limit ;-)

I don't think the extra words add much, if I saw "'Limit" and I'd never
seen it before I'd simply look up the RM. There are loads of existing
attribute names that could be wordier to be made clearer...


> > While that's good technique, I presume your NOT saying that the RM would
> > require this?
> 
> I thinkj it would be necessary to adopt this approach, since the base range 
> required cannot be guessed. I think the neatest solution is to require a 
> named type with this range to be declared, and then subtypes with the 
> required limited ranges to be declared and used to indicate the bounds of 
> the operation.

No it isn't - like I said in my original post, it can all be done with
generics as it is - it's just a pain to have to keep including new
instances when it could easily be part of the language - see example
at the end of this reply.


> > Also, why not allow it for any scalar type?
> 
> Yes, I think you're right. Shall I send a proposal to ada-comment?

Ok :-)

-----------------------------
-- generic_limit_fixed.ads --
-----------------------------
generic
   type T is delta <>;
function Generic_Limit_Fixed (V : T'Base) return T;

-----------------------------
-- generic_limit_fixed.adb --
-----------------------------
function Generic_Limit_Fixed (V : T'Base) return T is
begin
   if V < T'First then
      return T'First;
   elsif V > T'Last then
      return T'Last;
   else
      return V;
   end if;
end Generic_Limit_Fixed;

-----------------------------
-- generic_limit_float.ads --
-----------------------------
generic
   type T is digits <>;
function Generic_Limit_Float (V : T'Base) return T;

-----------------------------
-- generic_limit_float.adb --
-----------------------------
function Generic_Limit_Float (V : T'Base) return T is
begin
   if V < T'First then
      return T'First;
   elsif V > T'Last then
      return T'Last;
   else
      return V;
   end if;
end Generic_Limit_Float;

---------------
-- tests.ads --
---------------
with Generic_Limit_Fixed;
with Generic_Limit_Float;

package Tests is

   type Safe_Fixed_Degrees is
      delta 0.125 range -180.00 .. 180.0;

   function Limit is
      new Generic_Limit_Fixed (Safe_Fixed_Degrees);

   type Safe_Float_Degrees is
      digits 6 range -180.00 .. 180.0;

   function Limit is
      new Generic_Limit_Float (Safe_Float_Degrees);

end Tests;

--------------
-- test.adb --
--------------
with Ada.Text_IO; use Ada.Text_IO;

with Tests; use Tests;

procedure Test is
   procedure Test_Float is
      A, B, C : Safe_Float_Degrees;
   begin
      B := 170.0;
      C := 50.0;
      A := Limit (B + C);
      Put_Line ("A =" & Safe_Float_Degrees'Image (A));
   end Test_Float;

   procedure Test_Fixed is
      A, B, C : Safe_Fixed_Degrees;
   begin
      B := 170.0;
      C := 50.0;
      A := Limit (B + C);
      Put_Line ("A =" & Safe_Fixed_Degrees'Image (A));
   end Test_Fixed;
begin
   Test_Float;
   Test_Fixed;
end Test;