Re: Out parameters in a function

[Ingo Marks <adv@region-nord.de>]

Nazgul wrote:

> Hi, I need to use an output parameter in an Ada function, something like
> 
> function ReadChar(f: File; c: out character) return boolean;
> 
> The function must return a boolean, so the only way to read the character
> is via the 'c' parameter. In other context, I use
> 
> function (something: tpSomething) return ...; where tpSomething is an
> access to a record type, and I can modify the contents of the record in
> the function, but if I use
> 
> function ReadChar(f: File; c: access character) return boolean;
> 
> the compiler gives an error when i do something like
> 
> c:=anything;
> 
> Is there any way of using c as an output parameter?
> 
> Thanks.

You can simulate out parameters in functions with access:

   procedure Test is

      function Increment (Var : access Integer; Max : Integer) 
         return Boolean 
      is
         Value : Integer renames Var.all;
      begin
         Value := Value + 1;
         return Value <= Max;
      end;

      X : aliased Integer := 0;

   begin
      for I in 1..5 loop
         if Increment (X'Access, 3) then
            Put_Line("ok");
         else
            Put_Line("overflow");
         end if;
      end loop;
   end Test;

Result:

ok
ok
ok
overflow
overflow

Sometimes it may be better to use exceptions in favor of boolean tests:

   procedure Test is

      procedure Increment (Value : in out Integer; Max : Integer) is
      begin
         Value := Value + 1;
         if Value > Max then
            raise Constraint_Error;
         end if;
      end;

      X : Integer := 0;

   begin
      for I in 1..5 loop
         begin
            Increment (X, 3);
            Put_Line("ok");
         exception when Constraint_Error =>
            Put_Line("overflow");
         end;
      end loop;
   end Test;

If you define your own integer type with range 1..3 then you can spare the 
conditional statement in the function. The program will raise a runtime 
constraint error automatically provided that you have used the necessary 
compiler options.

Regards,
Ingo