Re: float with 24-bit resolution

["Matthew Heaney" <matthewjheaney@earthlink.net>]

<mailbox@adrianhoe.nospam.com.my> wrote in message
news:3F3CCB0F.543478AF@adrianhoe.nospam.com.my...
> Hi,
>
> I looked through the LRM and searched CLA but I could not find any
> solution. Perhaps I've overlook somewhere.
>
> I need a float with 24-bit resolution. My data needs to be encoded into
> 24 bits at a scaling of 720 degrees / 2^24 bits with the most
> significant bit being the sign bit. This results in a value that ranges
> from +359.9999571 degrees (0x7FFFFF) to -360.0000000 degrees (0x800000)
> at increments of approximately 4.291534424e-5 degrees per bit.

You're not asking for a floating point type at all -- you're asking for a
fixed point type.

This type has the properties you specified:

   Degrees_Type_Delta : constant := 360.0 / 2**23;

   type Degrees_Type is
      delta Degrees_Type_Delta
     range -360.0 .. 360.0;

   for Degrees_Type'Small use Degrees_Type_Delta;

   for Degrees_Type'Size use 24;


Here is a test program, that dumps the bits of various values of
Degrees_Type:

with Ada.Text_IO;  use Ada.Text_IO;
with Ada.Unchecked_Conversion;

procedure Test_Fixed is

   Degrees_Type_Delta : constant := 360.0 / 2**23;

   type Degrees_Type is
      delta Degrees_Type_Delta
     range -360.0 .. 360.0;

   for Degrees_Type'Small use Degrees_Type_Delta;

   for Degrees_Type'Size use 24;

   type I24_Type is range -2**23 .. 2**23 - 1;
   for I24_Type'Size use 24;

   function To_I24 is
     new Ada.Unchecked_Conversion
     (Degrees_Type,
      I24_Type);

   package I24_IO is
     new Ada.Text_IO.Integer_IO (I24_Type);

   use I24_IO;

   package Degrees_IO is
     new Ada.Text_IO.Fixed_IO (Degrees_Type);

   use Degrees_IO;

   F : Degrees_Type;
   I : I24_Type;

begin

   F := 45.0;
   I := To_I24 (F);

   Put (F);  Put (' '); Put (I, Base => 16); New_Line;

   F := 90.0;
   I := To_I24 (F);

   Put (F);  Put (' '); Put (I, Base => 16); New_Line;

   F := 135.0;
   I := To_I24 (F);

   Put (F);  Put (' '); Put (I, Base => 16); New_Line;

   F := 180.0;
   I := To_I24 (F);

   Put (F);  Put (' '); Put (I, Base => 16); New_Line;

   F := 225.0;
   I := To_I24 (F);

   Put (F);  Put (' '); Put (I, Base => 16); New_Line;

   F := 270.0;
   I := To_I24 (F);

   Put (F);  Put (' '); Put (I, Base => 16); New_Line;

   F := Degrees_Type'Last;
   I := To_I24 (F);

   Put (F);  Put (' '); Put (I, Base => 16); New_Line;

   --negative values:

   F := -45.0;
   I := To_I24 (F);

   Put (F);  Put (' '); Put (I, Base => 16); New_Line;

   F := -90.0;
   I := To_I24 (F);

   Put (F);  Put (' '); Put (I, Base => 16); New_Line;

   F := -135.0;
   I := To_I24 (F);

   Put (F);  Put (' '); Put (I, Base => 16); New_Line;

   F := -180.0;
   I := To_I24 (F);

   Put (F);  Put (' '); Put (I, Base => 16); New_Line;

   F := -225.0;
   I := To_I24 (F);

   Put (F);  Put (' '); Put (I, Base => 16); New_Line;

   F := -270.0;
   I := To_I24 (F);

   Put (F);  Put (' '); Put (I, Base => 16); New_Line;

   F := Degrees_Type'First;
   I := To_I24 (F);

   Put (F);  Put (' '); Put (I, Base => 16); New_Line;

end Test_Fixed;