Re: Problems with Ada.Text_IO and strings.

[Jeffrey Carter <spam@spam.com>]

Ludovic Brenta wrote:

> I'm not going to post working code and do your homework for you, but
> here are hints you may find useful.
> 
> Hint 1:
> 
> declare
>    S : String (1 .. 20);
>    Last : Natural;
> begin
>    Ada.Text_IO.Get_Line (S, Last); -- User's input is S (S'First .. Last)
> end;
> 
> Hint 2: if Last = S'Last, then you will want to call
> Ada.Text_IO.Get_Line again to read the rest of the input, and
> concatenate this to S.
> 
> Hint 3: recursive calls are your friends.

I don't think this is what the OP is looking for (a Get_Line function).

One way to deal with this is to read into a really long String using 
Get_Line, then use Ada.Strings.Fixed.Move to transfer the value to the 
Name variable. It's unlikely that a user will type in 100 characters for 
a name; 1000 practically guarantees that Get_Line will get the entire line.

Another is to write Get_Line yourself, not because you need to, but 
because it helps you understand what Get_Line is doing:

procedure Get_Line (Item : out String; Last : out Natural) is
begin
    Last := Item'First - 1;

    Read : for I in Item'range loop
       if End_Of_Line then
          Skip_Line;

          return;
       end if;

       Get (Item (I) );
       Last := I;
    end loop Read;
end Get_Line;

The important point is that Skip_Line is only called inside the loop. 
The loop exits when Item is completely filled; Skip_Line is not called. 
If the loop exits, Last = Item'Last. Thus, if on return from Get_Line, 
Last = Item'Last, then there is at least an unprocessed line terminator 
in the buffer, possibly preceded by some unprocessed characters. You can 
get rid of these by calling Skip_Line yourself.

You can also write a procedure to deal with all of this:

procedure Get_Whole_Line (Item : out String; Last : out Natural) is
begin
    Get_Line (Item, Last);

    if Last = Item'Last then
       Skip_Line;
    end if;
end Get_Whole_Line;

-- 
Jeff Carter
"Go and boil your bottoms."
Monty Python & the Holy Grail
01