Re: Reflection (was: Re: The best thing/greatest feature summary)

["David C. Hoos, Sr." <david.c.hoos.sr@ada95.com>]

Here is what might be considered an improvement on your package:

with Ada.Tags;
generic
package Reflection is
   Unit_Name : constant String;
private -- Reflection
   type T is abstract tagged null record;
   S : constant String := Ada.Tags.Expanded_Name (T'Tag);
   Unit_Name : constant String := S (1 .. S'Last - 2);
end Reflection;
package One is
 procedure P;
 procedure Q;
end One;
with Reflection,
  Ada.Text_Io;
package body One is
 package Me is new Reflection;
 procedure P is
 begin
   Ada.Text_Io.Put_Line (Me.Unit_Name);
 end P;
 procedure Q is
   package Me is new Reflection;
 begin
   Ada.Text_Io.Put_Line (Me.Unit_Name);
 end Q;
end One;
with Reflection,
     One,
     Ada.Text_Io;
procedure Test_Reflection is
  package Me is new Reflection;
begin
  One.P;                               --> ONE.ME
  One.Q;                               --> ONE.Q.ME
  Ada.Text_Io.Put_Line (Me.Unit_Name); --> TEST_REFLECTION.ME
end Test_Reflection;

<tmoran@acm.org> wrote in message
news:0O9M5.381209$i5.6373651@news1.frmt1.sfba.home.com...
> >Or does instantiating this package within a routine actually work? (I
don't
> >have an Ada compiler near me at the moment.)
> Using Gnat 3.13p,
>
> with Ada.Tags;
> generic package Reflection is
>    Unit_Name : constant String;
> private -- Reflection
>    type T is abstract tagged null record;
>    Unit_Name : constant String := Ada.Tags.Expanded_Name (T'Tag);
> end Reflection;
>
> package one is
>  procedure p;
>  procedure q;
> end one;
>
> with reflection,
>      ada.text_io;
> package body one is
>  package me is new reflection;
>  procedure p is
>  begin ada.text_io.put_line(me.unit_name);end p;
>  procedure q is
>    package myself is new reflection;
>  begin
>    ada.text_io.put_line(myself.unit_name);
>  end q;
> end one;
>
> with reflection,
>      one,
>      ada.text_io;
> procedure test is
>   package me is new reflection;
> begin
>   one.p;                              --> ONE.ME.T
>   one.q;                              --> ONE.Q.MYSELF.T
>   ada.text_io.put_line(me.unit_name); --> TEST.ME.T
> end test;