Re: tagged record child: override constructor?

[Jeffrey Carter <spam@spam.com>]

sean.gilbertson@gmail.com wrote:
> I have a tagged record that is declared private, along with a
> constructor function which returns an instance.  I do this to enforce
> the assignment of several required fields in the record, so if you know
> how to do this another way, please let me know!

It depends on what you mean by "enforce the assignment of several 
required fields". It is impossible to force the client to call your 
function, though you can arrange things so that the type is useless to 
the client if the client doesn't first call your function.

If you have

    type T is private;
    function Make return T;

then you don't need Make at all. You can ensure the required fields are 
initialized through default values:

private
    type T is record
       X : Integer   := -37;
       Y : Character := '*';
       Z : Duration;
    end record;

(Note that this is a property of record types in general; whether your 
record type is tagged doesn't affect this.) If you have fields you can't 
easily initialize through defaults, you can use the initialization 
features of controlled types:

private
    type T is new Ada.Finalization.Controlled with record
       ...
    end record;

    procedure Initialize (Object : in out T);

Initialize is called for every object of type T when it is created.

On the other hand, if you mean the assignment of client-supplied values 
to the required components, your choices are more limited. If the values 
are such that they may be discriminants, then that's a way to force the 
client to supply them:

    type T (X : Integer) is private;

If your required fields cannot be discriminants, then things get more 
complicated. You can include a Boolean field, default initialized to 
False, which is set to True by your function. All other operations of 
the type then check this field, and raise an exception if it is False:

    type T is private;

    procedure Initialize (X : out T; ...);

    Not_Initialized : exception;

    procedure Op (X : in out T);

private
    type T is record
       Initialized : Boolean := False;
       ...
    end record;

...

procedure Initialize (X : out T; ...) is
    ...
begin -- Initialize
    X.Initialized := True;
    ...
end Initialize;

procedure Op (X : in out T) is
    ...
begin -- Op
    if not X.Initialized then
       raise Not_Initialized;
    end if;

    ...
end Op;

This makes the type useless unless an object is first initialized.

None of this has anything to do with the fact that if T is tagged and a 
primitive operation of T is a function that returns T, then, yes, you do 
have to override such functions for each child of T.

-- 
Jeffrey Carter
"Now go away or I shall taunt you a second time."
Monty Python and the Holy Grail
E-mail: jeffrey_r_carter-nr [commercial-at]
         raytheon [period | full stop] com