Re: Conditional compilation in Ada?

[Jeffrey Carter <spam@spam.com>]

jtg wrote:

> I am developing two applications which are very similar
> and share the same source code. The only difference is
> a small change in a fundamental data structure. Both versions of the
> data structure are mostly handled the same way (within thousands of
> lines of source code), but there are some 10 or 20 (number still
> growing) places where minor changes are necessary. What is worse,
> during the development every several hours I have to prepare
> and run both the applications. To do this, I have to perform
> "human preprocessing": find those places, comment lines
> for app1, and uncomment lines for app2. This is very error prone and
> I have already made a mistake.
> 
> Any hints?

Yes. Don't use preprocessing.

It sounds as if you have a good use for a variant record:

type Common_Stuff is record
    ...
end record;

type Variant_1_Stuff is record
    ...
end record;

type Variant_2_Stuff is record
    ...
end record;

type Data_Structure (Variant_1 : Boolean) is record
    Common : Common_Stuff;

    case Variant_1 is
    when True =>
       Var_1 : Variant_1_Stuff;
    when False =>
       Var_2 : Variant_2_Stuff;
    end case;
end record;

Then you can write

Variant_1 : constant Boolean := ...;

X : Data_Structure (Variant_1 => Variant_1);

...
Common_Processing (Common => X.Common);

if X.Variant_1 then
    Variant_1_Processing (Var_1 => X.Var_1);
else
    Variant_2_Processing (Var_2 => X.Var_2);
end if;

If you anticipate additional variants, it's probably better to use an 
enumeration type for the discriminant:

type Variant_ID is (Variant_1, Variant_2);

type Data_Structure (Variant : Variant_ID) ...

case X.Variant is
when Variant_1 =>
    Variant_1_Processing ...

This is easily expanded by adding additional variants, and the compiler 
will tell you if you've missed anything.

-- 
Jeff Carter
"I've got to stay here, but there's no reason
why you folks shouldn't go out into the lobby
until this thing blows over."
Horse Feathers
50