Re: Any easy/build-in construct to extract submatrices from larger matrix?

[stefan-lucks@see-the.signature]

On Mon, 25 Jun 2012, Nasser M. Abbasi wrote:

> Here is another one: Given a square matrix, determine if the
> matrix is diagonal or not.

This is an easy challenge.

Ada 2012 provides a reasonably simple way to do this:

1. Specify the type of the Matrix, e.g.,

     type Matrix is array (Positive range <>, Positive range <>) of Float;

2. Specify the precondition (optional):

     function Is_Diagonal (M: Matrix) return Boolean
       with Pre => M'First(1) = M'First(2) and M'Last(1) = M'Last(2);

3. Implement the function:

     function Is_Diagonal (M: Matrix) return Boolean is
        (for all I in M'Range(1)
           => (for all J in M'Range(2)
                 => (if I /= J then M(I, J) = 0.0)));

This is four lines -- but the last two or three lines could be squeezed 
into a single one, if all what matters is the line count, disregarding 
readability. 

> In Mathematica, this one line function does it
> 
> diagQ[m_] := m === DiagonalMatrix[Diagonal[m]]

The comparison with Mathematica is a bit unfair. It uses some auxiliary 
functions that are just there in Mathematica, and could be easily be 
implemented in Ada as well. 

And your estimate of 20 lines is excessive. Consider the following 
specifications:

      type Matrix is array(Positive range <>, Positive range <>) of Float;
      type Vector is array(Positive range <>) of Float;

      function Is_Diagonal (M: Matrix) return Boolean
         with Pre => M'First(1) = M'First(2) and M'Last(1) = M'Last(2);

      function Diagonal (M: Matrix) return Vector
         with Pre => M'First(1) = M'First(2) and M'Last(1) = M'Last(2);

      function Diagonal_Matrix(V: Vector) return Matrix;

Implementing all three functions in Ada takes just 19 lines (not counting 
the empty ones):

      function Diagonal(M: Matrix) return Vector is
         V: Vector(M'First(1) .. M'Last(1));
      begin
         for I in V'Range loop
            V(I) := M(I, I);
         end loop;
         return V;
      end Diagonal;

      function Diagonal_Matrix(V: Vector) return Matrix is
         M: Matrix(V'First .. V'Last, V'First .. V'Last)
           := (others => (others => 0.0));
      begin
         for I in V'Range loop
            M(I, I) := V(I);
         end loop;
         return M;
      end Diagonal_Matrix;

      function Is_Diagonal (M: Matrix) return Boolean is
         (M  = Diagonal_Matrix(Diagonal(M)));



-- 
---- Stefan.Lucks (at) uni-weimar.de, University of Weimar, Germany  ----
    <http://www.uni-weimar.de/cms/medien/mediensicherheit/home.html>
------  I  love  the  taste  of  Cryptanalysis  in  the  morning!  ------