Re: "Must instantiate controlled types at library level." Why?

[Jeffrey Carter <spam@spam.com>]

Peter C. Chapin wrote:

> I have a generic package that contains a controlled type. When I attempt to 
> instantiate that package in the declarative part of a procedure, GNAT 
> (v3.15p) tells me that I must instantiate controlled types at "library 
> level" (or something like that). I worked around this by creating a helper 
> package in which I did the instantiation and then used that helper package in 
> my procedure. However, this experience leads me to wonder why there is this 
> restriction on controlled types.

That's the correct way to create a controlled type. I know it's 
difficult to see why this is needed, but it's a feature of all tagged 
types, not just controlled types. Any tagged type declared at library 
level must be extended at library level. The declarative part of a 
subprogram, including a library level subprogram, is never at library level.

The problem is that a value of an extended type can be stored in a 
variable at a higher nesting level. This could result in dispatching to 
an operation that no longer exists and referencing variables that no 
longer exist. This is easier to demonstrate than describe:

package Library_Level is
    type Taggy is tagged null record;
    procedure Op (T : in out Taggy);

    type Taggy_Ptr is access all Taggy'Class;

    Ptr : Taggy_Ptr;
end Library_Level;

with Library_Level;
procedure Outer is
    procedure Inner is
       type Taggy_Ext is new Library_Level.Taggy with null record;
       -- Illegal type extension
       procedure Op (T : in out Taggy_Ext);

       I : Integer := 7;

       procedure Op (T : in out Taggy_Ext) is
       begin -- Op
          I := I + 1;
       end Op;

       V : Taggy_Ext;
    begin -- Inner
       Library_Level.Ptr := new Library_Level.Taggy'Class'(V);
    end Inner;
begin -- Outer
    Inner;
    Library_Level.Op (T => Library_Level.Ptr.all);
end Outer;

The call to Library_Level.Op would attempt to dispatch to 
Outer.Inner.Op, which is out of scope. The references to I in 
Outer.Inner.Op refer to a variable that no longer exists.

-- 
Jeff Carter
"Blessed is just about anyone with a vested interest in the status quo."
Monty Python's Life of Brian
73