Interfacing with C - pointer problem

Interfacing with C - pointer problem

[Gerd]

I try to call some C code, so I wrote me a simple interface, but it 
does not what I expected.

It looks like this:

  type LPSTR is access all String;

  procedure C_Func (x : LPSTR);  -- expects an address (C-pointer, 32-
bit)
  pragma Import (STDCALL, C_Func, "C_Func");

  procedure Q is
   data : aliased String := "ABC" & Ascii.Nul;

  begin
   C_Func (data'unchecked_access);
  end Q;

This does not work correct. What I found is, that data'Address is 32 
bit and LPSTR is 64 bit.

How to manage this?

I tried a "pragma Convention (C, LPSTR);" but this gives a warning. So 
what would be the right way?

Thanks in advance,
Gerd

Re: Interfacing with C - pointer problem

[Frank J. Lhota]

Try using the Interfaces.C.Strings facilities instead. 

Re: Interfacing with C - pointer problem

[tmoran]

>   type LPSTR is access all String;
>
> This does not work correct. What I found is, that data'Address is 32
> bit and LPSTR is 64 bit.
   Because LPSTR points to a dynamic size string and thus needs to
carry along bounds information.  A C LPSTR does not point to a dynamic
string, but instead points to a single character - the first in the
string.  So the match is
   type LPSTR is access Interfaces.C.Char;
   procedure C_Func (x : LPSTR);  -- expects an address (C-pointer, 32-bit)
and then
   data : Interfaces.C.char_array := Interfaces.C.To_C("ABC");
and
   C_Func (data(data'first)'unchecked_access);

Re: Interfacing with C - pointer problem

[Adam Beneschan]

On Jan 30, 1:10 pm, tmo...@acm.org wrote:
> >   type LPSTR is access all String;
>
> > This does not work correct. What I found is, that data'Address is 32
> > bit and LPSTR is 64 bit.
>
>    Because LPSTR points to a dynamic size string and thus needs to
> carry along bounds information.  A C LPSTR does not point to a dynamic
> string, but instead points to a single character - the first in the
> string.  So the match is
>    type LPSTR is access Interfaces.C.Char;
>    procedure C_Func (x : LPSTR);  -- expects an address (C-pointer, 32-bit)
> and then
>    data : Interfaces.C.char_array := Interfaces.C.To_C("ABC");
> and
>    C_Func (data(data'first)'unchecked_access);

Or perhaps better:

   procedure C_Func (x : Interfaces.C.Strings.chars_ptr);

   data : aliased Interfaces.C.char_array := Interfaces.C.To_C
("ABC");

   C_Func (Interfaces.C.Strings.To_Chars_Ptr (data'unchecked_access));

May as well use the stuff Ada provides for this exact purpose.

                          -- Adam

Re: Interfacing with C - pointer problem

[Jeffrey R. Carter]

Adam Beneschan wrote:
>>    type LPSTR is access Interfaces.C.Char;
>>    procedure C_Func (x : LPSTR);  -- expects an address (C-pointer, 32-bit)
>> and then
>>    data : Interfaces.C.char_array := Interfaces.C.To_C("ABC");
>> and
>>    C_Func (data(data'first)'unchecked_access);
> 
> Or perhaps better:
> 
>    procedure C_Func (x : Interfaces.C.Strings.chars_ptr);
> 
>    data : aliased Interfaces.C.char_array := Interfaces.C.To_C
> ("ABC");
> 
>    C_Func (Interfaces.C.Strings.To_Chars_Ptr (data'unchecked_access));
> 
> May as well use the stuff Ada provides for this exact purpose.

Right. Therefore, even better:

procedure C_Func (X : in Interfaces.C.Char_Array);
pragma Import (C, C_Func, ...);

Data : Interfaces.C.Char_Array := Interfaces.C.To_C ("ABC);

C_Func (X => Data);

The language passes this a a pointer to Data (Data'First). See ARM B.3 
(70): "An Ada parameter of an array type with component type T, of any 
mode, is passed as a t* argument to a C function, where t is the C type 
corresponding to the Ada type T."

-- 
Jeff Carter
"Alms for an ex-leper!"
Monty Python's Life of Brian
75