Re: Beginer problem: variable array size

[tmoran@acm.org]

>I'm not elite programmer but I only see a few ways to easily
  So because you don't know Ada you don't see how to do it simply, and
therefore Ada is terrible?  That makes a lot of sense.
  Assuming that, unlike your C++ case, you have no access to any
libraries, and trusting you won't hand it in for your homework, I point out:

with Ada.Text_IO;
procedure Munch is
  use Ada.Text_IO;
  package Int_IO is new Integer_IO(Integer);

  type List_Type is array (Integer range <>) of Integer;
  Empty_List: List_Type(1 .. 0);

  function Get return List_Type is
    Datum   : Integer;
  begin
    Put("Enter an integer, or 0 to quit:");
    Int_IO.Get(Datum);
    if Datum = 0 then
      return Empty_List;
    else
      return Datum & Get;
    end if;
  end Get;

  List : List_Type := Get;
  Temp : Integer;

begin
  for I in List'range loop
    for J in I + 1 .. List'Last loop
      if List(I) > List(J) then
        Temp := List(I);
        List(I) := List(J);
        List(J) := Temp;
      end if;
    end loop;
    Put_Line(Integer'Image(List(I)));
  end loop;
end Munch;