Re: Reflection (was: Re: The best thing/greatest feature summary)

["David C. Hoos, Sr." <david.c.hoos.sr@ada95.com>]

Sorry about the earlier post.  This was the improved version I meant to
post:

with Ada.Strings.Fixed;
with Ada.Tags;
generic
package Reflection is
  Name : constant String;
private -- Reflection
  type T is abstract tagged null record;
  S : constant String := Ada.Tags.Expanded_Name (T'Tag);
  Last : constant Positive := Ada.Strings.Fixed.Index
    (S (1 .. S'Last - 2), ".", Ada.Strings.Backward) - 1;
  Name : constant String := S (1 .. Last);
end Reflection;
package One is
procedure P;
procedure Q;
end One;
with Reflection,
  Ada.Text_IO;
package body One is
package Me is new Reflection;
procedure P is
begin
  Ada.Text_Io.Put_Line (Me.Name);
end P;
procedure Q is
  package Me is new Reflection;
begin
  Ada.Text_Io.Put_Line (Me.Name);
end Q;
end One;
with Reflection,
    One,
    Ada.Text_IO;
procedure Test_Reflection is
  package Me is new Reflection;
begin
  One.P;                          --> ONE
  One.Q;                          --> ONE.Q
  Ada.Text_IO.Put_Line (Me.Name); --> TEST_REFLECTION
end Test_Reflection;