Re: From Pascal to Ada

[Ludovic Brenta <ludovic@ludovic-brenta.org>]

j.khaldi@oltrelinux.com writes:
> Hi,
> how do you translate this Pascal code in Ada?
>
> type
>   realFunction = function(x: double): double;
>
> Thanks!

In Ada you cannot declare subprogram types, only access-to-subprogram
(aka "pointer to subprogram") types.  In this case, you would say

declare
   type Real_Function is access function (X : Long_Float) return Long_Float;

   function F (X : Long_Float) return Long_Float is
   begin
      return 42.0 * X;
   end F;

   type Vector is array (Positive range <>) of Long_Float;
   procedure Apply (Func : in Real_Function; To : in out Vector) is
   begin
      for J in To'Range loop
         To (J) := Func (To (J)); -- call the pointed-to function
      end loop;
   end Apply;

   V : Vector (1 .. 100);
begin
   Apply (Func => F'Access, To => V);
end;

However there are other ways.  Ada 2005 introduces anonymous
access-to-subprogram types:

procedure Apply (Func : access function (X : Long_Float) return Long_Float;
                 To : in out Vector);

And it has been possible to use generics since Ada 83:

generic
   with function Func (X : Long_Float) return Long_Float;
procedure Apply (To : in out Vector);

Why do you ask?

-- 
Ludovic Brenta.