Re: Maximum Number Of Tasks?

[Jacob Sparre Andersen <jacob@jacob-sparre.dk>]

FritzVonBraun wrote:

> I was wondering about the maximum number of tasks in Ada but I couldnt
> find any info.

Probably because it is both compiler, hardware and operating system
dependent.

> The question is, is a task in Ada technically similar to a thread in
> Windows under the hood?

That depends on which compiler you use.  Some (most?) versions of GNAT
use operating system threads to implement tasks.  Janus/Ada implements
tasks in its own run-time system.

> Threads are restricted by the stack size that each thread has
> reserved, so in practice the maximum number of threads is about 2000.

I just made a quick test on my laptop.  It appears that I can create
32041 tasks before I have to do something special to avoid problems.

The test was done on a Debian 7.2 system with the GNAT 4.6 compiler
distributed with Debian.

The test program:

with Ada.Text_IO; use Ada.Text_IO;

procedure Task_Demo is
   task type Demo_Task (Index : Positive) is
      entry Stop;
   end Demo_Task;
   type Demo_Task_Reference is access Demo_Task;

   task body Demo_Task is
   begin
      Put_Line (Positive'Image (Index) & " launched.");
      accept Stop;
      Put_Line (Positive'Image (Index) & " stopping.");
   exception
      when others =>
         Put_Line (Positive'Image (Index) & " terminated by an exception.");
   end Demo_Task;

   Collection : array (1 .. 32_041) of Demo_Task_Reference;
begin
   for I in Collection'Range loop
      Collection (I) := new Demo_Task (Index => I);
   end loop;

   delay 1.0;

   for I in Collection'Range loop
      Collection (I).Stop;
   end loop;
end Task_Demo;

Reducing the stack size for the individual tasks does not seem to make a
difference.

> The reason I'm asking is that I wonder if Ada provides a more
> comfortable solution to the thread pool problem. In C++ for example I
> create a number of threads roughly equal to the number of processor
> cores and then have a number of Jobs that are distributed over the
> threads and which implement a time sharing system by returning control
> to the thread which then assigns time to another Job.
>
> Would I have to do the same in Ada or are tasks meant to be "micro
> objects' of which many can be created and the Ada runtime does
> effectively what my threadpool system does in C++

That depends on your compiler.

Greetings,

Jacob
-- 
"Two silk worms had a race. They ended up in a tie."