Re: asynchronous task communication

[Georg Bauhaus <rm.dash-bauhaus@futureapps.de>]

On 31.12.12 01:16, Charles Hixson wrote:
>
> The only alternative that I've come up with is to have each task have an access variable to a protected type instance.  This can be done, but it makes the control in other parts of the program trickier.

You could make the letter actively deliver itself.

Just in case you do no want to write a mail box, as
suggested by J-P. Rosen.

package Letters is

    task type Receiver is
       entry Knock (Message : String);
    end Receiver;

    task type Letter (Recipient : access constant Receiver) is
       entry Write (Message : String);
    end Letter;

    task type Sender is
    end Sender;

end Letters;

package body Letters is

    type Text_Buffer is access constant String;
    type Letter_Pointer is access Letter;
    Receiver_In_Scope : aliased Receiver;

    task body Receiver is
    begin
       accept Knock (Message : String);
    end Receiver;

    task body Letter is
       Text : Text_Buffer;
    begin
       --  get written, then actively get sent, then be finished
       accept Write (Message : String) do
          Letter.Text := new String'(Message);
       end Write;
       Recipient.Knock (Text.all);
    end Letter;

    task body Sender is

       procedure Send;
       --  prepare a self-delivering letter

       procedure Send is
          Order : Letter_Pointer;
       begin
          Order := new Letter (Recipient => Receiver_In_Scope'Access);
          Order.Write ("Meet me at 10 o'clock!");
       end Send;

    begin
       null;  -- ...
       Send;
       null;  -- ...
    end Sender;

end Letters;