Re: FAQ and string functions

[tmoran@acm.org]

> > choice of "Fixed", "Bounded", or "Unbounded").
> I haven't been able to find any documentation on how to use these
> functions...
  The Ada.Strings.* are described in Appendix A of the ALRM (available
on-line) and ought to be in any complete Ada textbook.
  For iterating over tokens Ada.Strings.Fixed.Index might be more
convenient, as in:
with Ada.Strings.Fixed,
     Ada.Text_IO;
procedure Split is
  Test : constant String := "These are the times that try men's souls";
  Left : Natural := Test'first;
  Right : Natural;
begin
   while Left <= Test'last loop
     Right := Ada.Strings.Fixed.Index(Test(Left .. Test'last), " ");
     if Right = 0 then Right := Test'last+1;end if;
     Ada.Text_IO.Put_Line(Test(Left .. Right-1));
     Left := Right+1;
   end loop;
end Split;

>Also something else I have been trying to work out, is how to replace,
>say all instances of "/" in a string with, say "__".
with Ada.Text_IO,
     Ada.Strings.Fixed;
procedure Rep is
  Test : constant String := "now is the/a time for all/some good//men/women";
  function Replace(Source, Drop, Add : String) return String is
  -- replace each occurrence of Drop in Source with Add
  -- Note: The modified string is not rescanned, so, for instance,
  -- Replace("Hello World", Drop=>" ", Add=>"  "); will not
  -- attempt to insert an infinite number of blanks.
    Si : Natural := Ada.Strings.Fixed.Index(Source, Drop);
  begin
    if Si = 0 then
      return Source;
    else
      return Source(Source'First .. Si - 1)
             & Add
             & Replace(Source(Si + Drop'Length .. Source'Last), Drop, Add);
    end if;
  end Replace;
begin
  Ada.Text_IO.Put_Line(Replace(Test, Drop => "/", Add => "__"));
end Rep;