Re: How to put 200 into an integer sub-type of 16 bits (code included)

[Georg Bauhaus <rm.dash-bauhaus@futureapps.de>]

ChristopherL schrieb:
> On Jan 14, 12:41 pm, Adam Beneschan <a...@irvine.com> wrote:
>>  Which
>> bits do you want to copy? 
> 
> The ones containing the mantissa.

OK, here is some code to extract the exponent.

BTW,  consider giving the reference when you
quote from Wikipedia.
In this case the "general info" seems to have been pasted from
http://en.wikipedia.org/wiki/Floating_point#Internal_representation


with Interfaces;
with Ada.Unchecked_Conversion, Ada.Text_IO;

procedure Th is

   use Ada;

   Arg: Float;
   pragma Assert(Float'Size = 32);

   The_Bits : Interfaces.Unsigned_32;

   function Just_The_Bits is
      new Unchecked_Conversion (Source => Float,
                                Target => Interfaces.Unsigned_32);

   Result: Interfaces.Unsigned_8;

   package Bit_IO_8 is new Text_IO.Modular_IO (Interfaces.Unsigned_8);
   package Bit_IO_32 is new Text_IO.Modular_IO (Interfaces.Unsigned_32);

begin
   Arg := 200.0;
   The_Bits := Just_The_Bits(Arg);

   Text_IO.Put("starting from float ");
   Bit_IO_32.Put(The_Bits, Base => 2);
   Text_IO.Put_Line(" of bit size" & Natural'Image(Float'Size) & ",");
   Text_IO.Put_Line("for " & Float'Image(Arg) & ", bits 24 .. 31 give");

   The_Bits := Interfaces.Shift_Right(The_Bits, 23);
   Result := Interfaces.Unsigned_8(The_Bits);

   declare
      use type Interfaces.Unsigned_8;
   begin
      Bit_IO_8.Default_Width := 0;

      Text_IO.Put("decimal "); Bit_IO_8.Put(Result);
      Text_IO.Put(", that's "); Bit_IO_8.Put(Result - 127);
      Text_IO.Put_Line(" without bias");

      Text_IO.Put("binary "); Bit_IO_8.Put(Result, Base => 2);
      Text_IO.Put(", or ");  Bit_IO_8.Put(Result - 127, Base => 2);
      Text_IO.Put_Line(" without bias.");
   end;
end Th;