Re: Problem with tasks

["Frank J. Lhota" <NOSPAM.FrankLho@rcn.com>]

"Magik" <dormar00@poczta.onet.pl> wrote in message
news:chc076$i96$1@nemesis.news.tpi.pl...
> Hello.
>
> 1. Proces_Alarmu.Start -> Yes OK!
> 2. Proces_Alarmu.Stop -> Yes OK!
> But
> 3. Proces_Alarmu.Start - Why does not start again exercise?

Because Proces_Alarmu was not written that way. After the Stop entry was
called, the Proces_Alarmu task exits the loop and finishes its body of code.
Task entries do NOT work like external "goto" statements: if you want
Proces_Alarmu to service the Start entry, then the code for Proces_Alarmu
must be able to get to an "accept Start" call.

Whenever one has a problem of this sort, it is advisable to include a
description of how you want the task to behave. Assuming that Proces_Alarmu
is supposed to alternately accept Start and Stop entries, and print "test"
once a second until the Stop entry was called, then Proces_Alarmu could be
written like this:

task Proces_Alarmu is
   entry Start;
   entry Stop;
end Proces_Alarmu;

task body Proces_Alarmu is
begin
   For_Each_Start_Stop:
   loop
      accept Start;
      Until_Stop:
      loop
         select
            accept Stop;
            exit;
         or
            delay 1.0;
            put("test");
         end select;
      end loop Until_Stop;
   end loop For_Each_Start_Stop;
end Proces_Alarmu;