Re: Returning a function

["Marc A. Criley" <mcqada@earthlink.net>]

"Hoffmann, Torben" wrote:
> 
> Hi.
> 
> I would like to do some higher-order functions in Ada (just for the fun of
> it) - could anyone give me a link which provides information on how to
> return a function from a function (or procedure).
> 
> Thanks in advance
> /Torben

Here's a quick example:

procedure FF is

   type Operations is (Check_Positive, Check_Even);

   type A_Function_Type is access function(X : Integer) return Boolean;

   function Is_Positive (A : Integer) return Boolean is
   begin
      return A > 0;
   end Is_Positive;

   function Is_Even (Z : Integer) return Boolean is
   begin
      return (Z mod 2) = 0;
   end Is_Even;


   function Select_Function(Op : Operations) return A_Function_Type is
   begin
      if Op = Check_Positive then
         return Is_Positive'Access;
      elsif Op = Check_Even then
         return Is_Even'Access;
      end if;
   end Select_Function;

   AFT : A_Function_Type;

   Result : Boolean;

begin
   -- Storing the function in a variable, and then
   -- invoking it.
   AFT := Select_Function(Check_Positive);
   Result := AFT.all(-19);

   AFT := Select_Function(Check_Even);
   Result := AFT.all(-19);

   -- Calling it directly via the retrieval function
   Result := Select_Function(Check_Positive).all(38);
end FF;


Marc A. Criley
Senior Staff Engineer
Quadrus Corporation
www.quadruscorp.com