Re: task activation

[Mats Weber <matsw@mail.com>]

Matthew Heaney wrote:

> A few posts ago Robert Dewar made a comment about the problems you can
> have if you call a procedure as soon as the task has activated.  For
> example:
> 
> with P;
> package body Q is
> 
>   task O;
> 
>   task body O is
>   begin
>     P.Op;
>   end;
> 
> end Q;
> 
> I think what Robert was saying was that you have no guarantee that the
> body of P has been elaborated yet.  So if (activated) task O tries to
> call an operation provided by P, then you can get Program_Error.  Is
> this analysis correct?

Yes.

> What is the solution:
> 
> 1) Elaborate(all) the packages you call, ie
> 
> with P;
> pragma Elaborate_All (P);
> 
> package body Q is
> 
>   task O;
> 
>   task body O is
>   begin
>     P.Op;
>   end;
> 
> end Q;
> 
> Will this work OK?  Or will it constrain the elaboration order
> unnecessarily?

It will work OK, and Elaborate_All is just the right pragma, you need no
more, no less.

> 2) No, don't elaborate the packages.  Wait to be told (by the Ada main
> perhaps, which follows elaboration of all packages) that it's OK to
> start:
> 
> with P;
> package body Q is
>   protected Initialization is
>     procedure Signal;
>     entry Wait;
>   private
>     OK_To_Start : Boolean := False;
>   end;
>   ...
>   task body O is
>   begin
>     Initialization.Wait;
>     P.Op;
>   end;
> 
> end Q;

That will work fine too , but you can do it without a protected object:

package P is

   procedure Start;  -- to be called after elaboration.

end P;

with P;
package body Q is

  task O is
    entry Start;
  end O;

  procedure Start is
  begin
     O.Start;
  end;

  task body O is
  begin
    accept Start;
    P.Op;
  end;

end Q;