Re: Subverting 'Access for Sub-programs

["Michael F. Yoder" <yoder@decada.zko.dec.com>]

Anton Gibbs wrote:
> 
> Dear Ada Community,
> 
> Can someone please advise me on the best way to subvert the language
> rules that prevent the use of 'Access on a locally declared procedure?
> ...

Is the following rearranged version, which compiled and ran using GNAT,
sufficient?  If not, is there something missing from your example that
shows your problem more exactly?

package Database is
   type Action_Type is access procedure( I : in Integer );
   -- Perform calls Action for every entry in the database
   procedure Perform( Action : in Action_Type );
end Database;

package body Database is
   procedure Perform( Action : in Action_Type ) is
   begin
      for I in 1 .. 10 loop
         Action.all(I);
      end loop;
   end Perform;
end Database;

package p is
   procedure Print_If_Even( I : in Integer );
end p;

with Ada.Text_IO;
package body p is
   procedure Print_If_Even( I : in Integer ) is
   begin
      if I rem 2 = 0 then
         Ada.Text_IO.Put_Line( Integer'Image( I ) );
      end if;
   end Print_If_Even;
end p;

with Database;
with p;
procedure Main is
begin
   Database.Perform( Action => p.Print_If_Even'Access );
end Main;

-- 
Michael F. Yoder

Unscientific man is beset by a deplorable desire to have been right.
The scientist is distinguished by a desire to *be* right. -- W.V. Quine