Making a nonlimited type controlled by means of a controlled component

[Ludovic Brenta <ludovic@ludovic-brenta.org>]

AdaMagica wrote on comp.lang.ada:
> Hu Ludovic ,
>
> that's dangerous what you proposed:
> -----------------------------------
> private with Ada.Finalization;
>
> package Ludovic is
>
>   type T is private;
>
>   -- primitive operations here
>   procedure Show (X: in T);
>
> private
>
>   type Controller (Enclosing: access T) is new
> Ada.Finalization.Controlled with null record;
>
>   overriding procedure Initialize (This: in out Controller);
>   overriding procedure Adjust     (This: in out Controller);
>   overriding procedure Finalize   (This: in out Controller);
>
>   type T is record -- note: untagged record
>     C: Controller (Enclosing => T'Access);
>     I: Integer;
>   end record;
>
> end Ludovic;
> with Ada.Text_IO;
> use  Ada.Text_IO;
>
> package body Ludovic is
>
>   I: Integer := 0;
>
>   overriding procedure Initialize (This: in out Controller) is
>   begin
>     I := I + 1;
>     This.Enclosing.I := I;
>   end Initialize;
>
>   overriding procedure Adjust (This: in out Controller) is
>   begin
>     This.Enclosing.I := This.Enclosing.I + 1;
>   end Adjust;
>
>   overriding procedure Finalize (This: in out Controller) is
>   begin
>     null;
>   end Finalize;
>
>   procedure Show (X: in T) is
>   begin
>     Put_Line (Integer'Image (X.I) & Integer'Image (X.C.Enclosing.I));
>   end Show;
>
> end Ludovic;
> with Ada.Text_IO;
> use  Ada.Text_IO;
>
> with Ludovic;
>
> procedure Brenta is
>
>   X, Y: Ludovic.T;
>
> begin
>
>   Ludovic.Show (X);
>   Ludovic.Show (Y);
>   New_Line;
>
>   X := Y;
>   Ludovic.Show (X);  -- X.C points to Y - that's surely not what you
> want.
>   Ludovic.Show (Y);
>   New_Line;
>
> end Brenta;

Darn, you're right. I hadn't thought of that. Now I understand why Ada
95 requires T to be limited (in this case the problem goes away, since
assignment is forbidden).  What worries me the most is that AI402,
which allowed access discriminants on nonlimited types, does not
mention this issue at all.

http://www.ada-auth.org/cgi-bin/cvsweb.cgi/ais/ai-00402.txt?rev=1.5

Randy, do you have an opinion on this, or should I raise the problem
with the ARG?

--
Ludovic Brenta.