Re: How to interface in ADA with Microsoft joystick?

["Dmitry A. Kazakov" <mailbox@dmitry-kazakov.de>]

On Tue, 12 Oct 2010 10:41:17 -0700 (PDT), tolkamp wrote:

> Building of project gives the result:
> 
> gnatmake -d -PC:\GNAT\2010\bin\joystick.gpr -XLIBRARY_TYPE=static
> joystick_main.adb
> gnatbind -I- -x C:\GNAT\2010\bin\joystick_main.ali
> error: "win32-mmsystem.adb" must be recompiled ("win32-mmsystem.ads"
> has been modified)
> gnatmake: *** bind failed.

Sorry, but it still is broken.

Here is a complete working example of using joystick under GNAT Ada and
Win32Ada:

---------- joystick.gpr --------------------------------------

with "win32ada.gpr";
project Joystick is
   for Source_Dirs use (".");
   for Main use ("joystick_main.adb");
   package Linker is
      for Default_Switches ("ada") use ("-lwinmm", "-mwindows");
   end Linker;
end Joystick;

---------- joystick_main.adb ------------------------------

with Ada.Strings.Unbounded;  use Ada.Strings.Unbounded;
with Interfaces.C;           use Interfaces.C;
with Win32;                  use Win32;
with Win32.MMSystem;         use Win32.MMSystem;
with Win32.WinUser;          use Win32.Winuser;
with System;                 use System;

procedure Joystick_Main is
   State  : aliased JOYINFO;
   Result : MMRESULT;
   Text   : Unbounded_String;
begin
   loop
      Text := Null_Unbounded_String;
      Result := joyGetPos (JOYSTICKID1, State'Unchecked_Access);
      if Result = JOYERR_NOERROR then
         Append (Text, "X =" & UINT'Image (State.wXpos));
         Append (Text, "Y =" & UINT'Image (State.wYpos));
      else
         Append (Text, "Error reading joystick state");
      end if;
      Append (Text, Character'Val (0));
      case MessageBox
           (  Null_Address,
              Addr (To_String (Text)),
              Addr ("Joystick position" & Character'Val (0)),
              MB_OKCANCEL
           )  is
         when IDOK   => null;
         when others => exit;
      end case;
   end loop; 
end Joystick_Main;

-------------------------------------------------------------------

The example uses joyGetPos because joyGetPosEx would not work with most of
joysticks.

-- 
Regards,
Dmitry A. Kazakov
http://www.dmitry-kazakov.de