Re: conversions between fixed-point types

[sjw <simon.j.wright@mac.com>]

On Sep 18, 10:35 pm, Dirk Herrmann <fight_s...@invalid.invalid> wrote:

> I realized that with GNAT for the following example types
>     type FpA is delta 0.5 range -10.0 .. +10.0;
>     for FpA'Small use 0.5;
>     type FpB is delta 0.4 range -10.0 .. +10.0;
>     for FpB'Small use 0.4;
> conversions from FpA to FpB work as follows:
>
>     FpA       FpB
>     -1.5 ---> -1.2
>     -1.0 ---> -0.8
>     -0.5 ---> -0.4
>     -0.0 ---> -0.0
>     +0.5 ---> +0.4
>     +1.0 ---> +0.8
>     +1.5 ---> +1.2
>
> That is, the conversion is performed similar to a truncation (always
> choosing the closest value towards zero).

I don't see this; GNAT rounds ..

with Ada.Text_IO; use Ada.Text_IO;
procedure Fixed
is
   type FpA is delta 0.5 range -10.0 .. +10.0;
   for FpA'Small use 0.5;
   type FpB is delta 0.4 range -10.0 .. +10.0;
   for FpB'Small use 0.4;
   F : FpA'Base;
   G : FpB'Base;
begin
   F := -3.0;
   loop
      exit when F > 3.0;
      Put_Line
        (FpA'Image (F)
           & " "
           & FpB'Image (FpB (F))
           & " "
           & FpA'Image (FpA (FpB (F))));
      F := FpA'Succ (F);
   end loop;
   New_Line;
   G := -2.8;
   loop
      exit when G > 2.8;
      Put_Line
        (FpB'Image (G)
           & " "
           & FpA'Image (FpA (G))
           & " "
           & FpB'Image (FpB (FpA (G))));
      G := FpB'Succ (G);
   end loop;
end Fixed;

The output (Mac OS X, gcc-4.3.3 and GNAT-GPL-2009) is below, I've
noted the differences with ?'s:

-3.0 -3.2 -3.0      rounded away from 0
-2.5 -2.4 -2.5
-2.0 -2.0 -2.0
-1.5 -1.6 -1.5      " ?
-1.0 -1.2 -1.0      " ?
-0.5 -0.4 -0.5
 0.0  0.0  0.0
 0.5  0.4  0.5
 1.0  1.2  1.0      " ?
 1.5  1.6  1.5      " ?
 2.0  2.0  2.0
 2.5  2.4  2.5
 3.0  3.2  3.0      "

-2.8 -3.0 -3.2      " and final value /= initial value
-2.4 -2.5 -2.4      "
-2.0 -2.0 -2.0
-1.6 -1.5 -1.6
-1.2 -1.0 -1.2
-0.8 -1.0 -1.2      " "
-0.4 -0.5 -0.4      "
 0.0  0.0  0.0
 0.4  0.5  0.4
 0.8  1.0  1.2      " "
 1.2  1.0  1.2
 1.6  1.5  1.6
 2.0  2.0  2.0
 2.4  2.5  2.4      "
 2.8  3.0  3.2      " "