Re: How do you bitwise operations in Ada '83 and '95

["jimmaureenrogers@worldnet.att.net" <jimmaureenrogers@worldnet.att.net>]

Chris L wrote:
> Also, do you have small coding examples that demonstrate this?

Bitwise operations in Ada 83 are accomplished through packed
arrays of boolean. In Ada 95 you can also accomplish
bit-wise operations (and, or, xor) on modular types.

The following example shows bit-wise operations using a
packed array of boolean. The small program computes prime
number using a sieve of Erastosthenese. The array flagging
found values is implemented as a packed array of boolean.

Notice that individual bits are directly addressable as array
elements in a packed array of boolean.

with Ada.Command_Line;use Ada.Command_Line;
with Ada.Text_Io;use Ada.Text_Io;
with Ada.Integer_Text_Io;use Ada.Integer_Text_Io;

procedure Nsievebits is

   function Count (M : in     Natural ) return Natural is
      type Boolean_Array is array (2 .. M) of Boolean;
      pragma Pack (Boolean_Array);
      C : Natural       := 0;
      S : Boolean_Array := (others => True);
      I : Positive;
   begin
      for K in S'range loop
         if S(K) then
            C := C + 1;
            I := K;
            loop
               I := I + K;
               exit when I > M;
               S(I) := False;
            end loop;
         end if;
      end loop;
      return C;
   end Count;

   procedure Run (N : in     Natural ) is
      M : Natural;
   begin
      M := 2 ** N * 10_000;
      Put ("Primes up to ");
      Put (Item  => M, Width => 8);
      Put (Item  => Count (M), Width => 8);
      New_Line;
   end Run;

   N : constant Natural := Natural'Value (Argument (1));
begin
   Run (N);
   Run (N - 1);
   Run (N - 2);
end Nsievebits; 
   
Jim Rogers