How to extract range from array

How to extract range from array

[Maciej Sobczak]

Hi,

Consider this:

    type My_Range is range 1..10;
    type My_Array is array(My_Range) of Integer;

now, the other way round:

    type My_Array is array(1..10) of Integer;
    type My_Range is ???;

In this second example I would like to extract the type of range from 
the already defined array type and give it a name. Is it possible? How?


-- 
Maciej Sobczak : http://www.msobczak.com/
Programming    : http://www.msobczak.com/prog/

Re: How to extract range from array

[Ed Falis]

On Fri, 17 Mar 2006 06:23:40 -0500, Maciej Sobczak <no.spam@no.spam.com>  
wrote:

> type My_Array is array(1..10) of Integer;
>    type My_Range is ???;

type My_Range is new Integer range My_Array'Range;

However, if you intend to use My_Range to index an object of type  
My_Array, the following is more useful because it won't require a type  
conversion to integer:

subtype My_Range is Integer range My_Array'Range;

Re: How to extract range from array

[Martin Krischik]

Hi

Read:

http://en.wikibooks.org/wiki/Ada_Programming/Types/array#Array_Attributes

Martin

Re: How to extract range from array

[Maciej Sobczak]

Martin Krischik wrote:

> Read:
> 
> http://en.wikibooks.org/wiki/Ada_Programming/Types/array#Array_Attributes

Thank you, this is exactly what I was missing - the constraining of the 
Integer part, and thought that it can be done by just simple attribute 
usage, like in:

type My_Range is My_Array'Range;

which does not work.


-- 
Maciej Sobczak : http://www.msobczak.com/
Programming    : http://www.msobczak.com/prog/

Re: How to extract range from array

[Maciej Sobczak]

Martin Krischik wrote:

> Read:
> 
> http://en.wikibooks.org/wiki/Ada_Programming/Types/array#Array_Attributes

subtype My_Range is Integer range My_Array'Range;

This suggests that arrays cannot have more elements than Integer'Last.
Which cannot be true.

What am I missing?

-- 
Maciej Sobczak : http://www.msobczak.com/
Programming    : http://www.msobczak.com/prog/

Re: How to extract range from array

[Ed Falis]

On Mon, 20 Mar 2006 08:14:37 -0500, Maciej Sobczak <no.spam@no.spam.com>  
wrote:

> subtype My_Range is Integer range My_Array'Range;
>
> This suggests that arrays cannot have more elements than Integer'Last.
> Which cannot be true.
>
> What am I missing?

That the above was an example.  You could also do:

subtype My_Range is Interfaces.Integer_64 range My_Array'Range;
subtype My_Range is Interfaces.Unsigned_64 range My_Array'Range;

or any other integer or modular type that is used to define the index of  
My_Array.

- Ed

Re: How to extract range from array

[Dmitry A. Kazakov]

On Mon, 20 Mar 2006 14:14:37 +0100, Maciej Sobczak wrote:

> subtype My_Range is Integer range My_Array'Range;
> 
> This suggests that arrays cannot have more elements than Integer'Last.
> Which cannot be true.
> 
> What am I missing?

A'Range is not a [sub]type, it is a value of some anonymous "range-type."
What you need is:

subtype My_Range is My_Array'Index range My_Array'Range;
   -- This is not Ada!

alas. This is also why you cannot:

generic
   type My_Array is array (<>) of Something; -- Not Ada!

Ada does not have array interfaces. So you have to specify the index type
instead of asking it from the array's instance:

generic
   type My_Index is ...;
   type My_Array is array (My_Index range <>) of Something;

-- 
Regards,
Dmitry A. Kazakov
http://www.dmitry-kazakov.de

Re: How to extract range from array

[Robert A Duff]

Maciej Sobczak <no.spam@no.spam.com> writes:

> What am I missing?

type T is array(1..10) of ...;

means the same as:

type T is array(Integer range 1..10) of ...;

which is a kludge.  I always write the latter (in the rare case where I
want Integer).  But you can say:

    type Index is range 1..Integer'Last + 1;
    type T is array(Index) of ...;
    X: T;

presuming System.Max_Int > Integer'Last,
and presuming you have enough memory to store the array.

- Bob

Re: How to extract range from array

[Martin Krischik]

Maciej Sobczak wrote:

> Martin Krischik wrote:
> 
>> Read:
>> 
>> http://en.wikibooks.org/wiki/Ada_Programming/Types/array#Array_Attributes
> 
> subtype My_Range is Integer range My_Array'Range;
> 
> This suggests that arrays cannot have more elements than Integer'Last.
> Which cannot be true.

You should have copied the original example: 

Hello_World  : const String := "Hello World!";
subtype Hello_World_Index is Integer range Hello_World'Range;

> What am I missing?

You are missing the definition of String which is part of Standard:

http://en.wikibooks.org/wiki/Ada_Programming/Libraries/Standard

and reads something like this (on GNAT):

 type Integer is range -(2 ** 31) .. +(2 ** 31 - 1);
 subtype Positive is Integer range 1 .. +(2 ** 31 - 1);

 type String is array (Positive range <>) of Character;
 pragma Pack (String);

And indeed the array in the example can not be larger then Integer'Last
because Strings are not larger then Integer'Last.

Of corse you could define:

 type Long_Long_Integer   is range -(2 ** 63) .. +(2 ** 63 - 1);
 subtype Long_Long_Positive is Integer range 1 .. +(2 ** 63 - 1);

 type Long_Long_String is array (Long_Long_Positive range <>) of Character;
 pragma Pack (Long_Long_String);

And then order additional memory for your computer to store
Long_Long_String's in  ;-)

Martin
-- 
mailto://krischik@users.sourceforge.net
Ada programming at: http://ada.krischik.com

Re: How to extract range from array

[Georg Bauhaus]

Martin Krischik wrote:

>  type Long_Long_String is array (Long_Long_Positive range <>) of Character;
>  pragma Pack (Long_Long_String);
> 
> And then order additional memory for your computer to store
> Long_Long_String's in  ;-)


with Google;
package Big_Ones is

   type Huge is range 1 .. 10**66;

   type Long_Long_String is array(Huge range <>) of Character;
   type Text is access Long_Long_String;

   for Text'Storage_Pool use Google.Net;

end Big_Ones;


Given a suitable compiler for distributed sytems...  ;)


 Georg 

Re: How to extract range from array

[Jeffrey R. Carter]

Martin Krischik wrote:
> 
>  subtype Positive is Integer range 1 .. +(2 ** 31 - 1);

The declaration of Positive is defined by ARM A.1, and so is the same for all 
implementations:

subtype Positive is Integer range 1 .. Integer'Last;

An implementation that used +(2 ** 31 - 1) instead of Integer'Last would not be Ada.

Of course, the meaning of Integer'Last depends on the definition of Integer, 
which is implementation defined, but the declaration of Positive is the same.

-- 
Jeff Carter
"From this day on, the official language of San Marcos will be Swedish."
Bananas
28

Re: How to extract range from array

[Martin Krischik]

Jeffrey R. Carter wrote:

> Martin Krischik wrote:
>> 
>>  subtype Positive is Integer range 1 .. +(2 ** 31 - 1);
> 
> The declaration of Positive is defined by ARM A.1, and so is the same for
> all implementations:
> 
> subtype Positive is Integer range 1 .. Integer'Last;
> 
> An implementation that used +(2 ** 31 - 1) instead of Integer'Last would
> not be Ada.

No it's GNAT ;-) .

Martin
-- 
mailto://krischik@users.sourceforge.net
Ada programming at: http://ada.krischik.com